4 files changed, 193 insertions, 0 deletions
diff --git a/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.12.bb b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.12.bb
new file mode 100644
index 00000000..b10cd997
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.1.12.bb
@@ -0,0 +1,45 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX DPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=44a8052c384584ba09077e85a3d1654f"
+
+DEPENDS = "libdrm ${LIBGAL_IMX}"
+LIBGAL_IMX              = "libgal-imx"
+LIBGAL_IMX:mx95-nxp-bsp = ""
+
+PROVIDES += "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;fsl-eula=true;name=${IMX_SRC_URI_NAME}"
+IMX_BIN_NAME = "${BPN}-${IMX_SRC_URI_NAME}-${PV}-${IMX_SRCREV_ABBREV}"
+
+IMX_SRCREV_ABBREV = "ee47ef7"
+IMX_SRC_URI_NAME = "v1"
+SRC_URI[v1.md5sum] = "4150f09e27178101fdccb792b7cbc526"
+SRC_URI[v1.sha256sum] = "bd7849376564f7e2eb55210f156afae00b49451de6de80cfbc5fbda15be6a2b0"
+
+IMX_SRCREV_ABBREV:mx95-nxp-bsp = "ee47ef7"
+IMX_SRC_URI_NAME:mx95-nxp-bsp = "v2"
+SRC_URI[v2.md5sum] = "031396e175c432eb6c84aad8e0a6fc7d"
+SRC_URI[v2.sha256sum] = "0646d8cc8e53f22fc15a61f0b78cd5f73460520f91949bc1d29c10ecbf77307b"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+COMPATIBLE_MACHINE = "(imxdpu)"
diff --git a/recipes-graphics/imx-g2d/imx-g2d-samples_git.bb b/recipes-graphics/imx-g2d/imx-g2d-samples_git.bb
new file mode 100644
index 00000000..55f88da3
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-g2d-samples_git.bb
@@ -0,0 +1,76 @@
+SUMMARY = "i.MX G2D Samples"
+DESCRIPTION = "Set of sample applications for i.MX G2D"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=0858ec9c7a80c4a2cf16e4f825a2cc91"
+
+DEPENDS = "cairo"
+
+PV = "2.1+git${SRCPV}"
+
+SRC_URI = "${GPU_G2D_SAMPLES_SRC};branch=${SRCBRANCH}"
+GPU_G2D_SAMPLES_SRC ?= "git://github.com/nxp-imx/g2d-samples.git;protocol=https"
+SRCBRANCH = "imx_2.1"
+SRCREV = "bec2f3839737b0e83b68b1c976373d9a78e5762f"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig
+
+PACKAGECONFIG ??= "${PACKAGECONFIG_IMPLEMENTATION}"
+PACKAGECONFIG_IMPLEMENTATION                   = ""
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxdpu   = "dpu"
+PACKAGECONFIG_IMPLEMENTATION:mx95-nxp-bsp      = "dpu95"
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d          = "gpu-drm"
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxfbdev = "gpu-fbdev"
+PACKAGECONFIG_IMPLEMENTATION:mx93-nxp-bsp      = "pxp"
+
+PACKAGECONFIG[dpu] = " \
+    BUILD_IMPLEMENTATION=dpu, \
+    , \
+    imx-dpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu95 gpu-drm gpu-fbdev pxp"
+PACKAGECONFIG[dpu95] = " \
+    BUILD_IMPLEMENTATION=dpu95, \
+    , \
+    imx-dpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu gpu-drm gpu-fbdev pxp"
+PACKAGECONFIG[gpu-drm] = " \
+    BUILD_IMPLEMENTATION=gpu-drm, \
+    , \
+    imx-gpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu dpu95 gpu-fbdev pxp"
+PACKAGECONFIG[gpu-fbdev] = " \
+    BUILD_IMPLEMENTATION=gpu-fbdev, \
+    , \
+    imx-gpu-g2d, \
+    , \
+    , \
+    dpu dpu95 gpu-drm pxp"
+PACKAGECONFIG[pxp] = " \
+    BUILD_IMPLEMENTATION=pxp, \
+    , \
+    imx-pxp-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu dpu95 gpu-drm gpu-fbdev"
+
+EXTRA_OEMAKE += " \
+    SDKTARGETSYSROOT=${STAGING_DIR_HOST} \
+    ${PACKAGECONFIG_CONFARGS} \
+"
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}
+
+FILES:${PN} += "/opt"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE = "(imxgpu2d|mx93-nxp-bsp|mx95-nxp-bsp)"
diff --git a/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.11.p2.4.bb b/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.11.p2.4.bb
new file mode 100644
index 00000000..3ebb8f88
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.11.p2.4.bb
@@ -0,0 +1,44 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX GPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=44a8052c384584ba09077e85a3d1654f"
+DEPENDS = "libgal-imx"
+PROVIDES = "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;name=${TARGET_ARCH};fsl-eula=true"
+IMX_BIN_NAME = "${BP}-${TARGET_ARCH}-${IMX_SRCREV_ABBREV}"
+IMX_SRCREV_ABBREV = "b07999b"
+SRC_URI[aarch64.md5sum] = "fa30ce75803697d5131d707b300258ee"
+SRC_URI[aarch64.sha256sum] = "2dff0279ead132ec5fa61dbe9b2b1969135e8ce9fe7487957371327357d70ac7"
+SRC_URI[arm.md5sum] = "c81be7c93b60c7d3f3eb5b7bfeda42a4"
+SRC_URI[arm.sha256sum] = "e17ac373193622ec0c9aa490ef1b93551d22a2e88ee9f1098ed984e62f02a06c"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+SOC_INSTALL_DIR               = "SOC_INSTALL_DIR_NOT_SET"
+SOC_INSTALL_DIR:mx8mm-nxp-bsp = "mx8mm"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    if [ -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR} ]; then
+        cp -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR}/*.so* ${D}${libdir}
+    fi
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxgpu2d)"
diff --git a/recipes-graphics/imx-g2d/imx-pxp-g2d_git.bb b/recipes-graphics/imx-g2d/imx-pxp-g2d_git.bb
new file mode 100644
index 00000000..50c37a2c
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-pxp-g2d_git.bb
@@ -0,0 +1,28 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2023 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX PXP"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=44a8052c384584ba09077e85a3d1654f"
+
+PROVIDES += "virtual/libg2d"
+
+PV = "2.1.0+git${SRCPV}"
+
+SRC_URI = "${IMX_PXP_G2D_SRC};branch=${SRCBRANCH}"
+IMX_PXP_G2D_SRC ?= "git://github.com/nxp-imx/imx-g2d-pxp.git;protocol=https"
+SRCBRANCH = "imx_2.1"
+SRCREV = "9f9f41fa0e86757f856e1ec7824f56022fe94586"
+
+S = "${WORKDIR}/git"
+
+inherit use-imx-headers
+
+EXTRA_OEMAKE = "PLATFORM=IMX93 INCLUDE='-I${STAGING_INCDIR_IMX}' DEST_DIR=${D}"
+
+do_install() {
+    oe_runmake install
+}
+
+COMPATIBLE_MACHINE = "(mx93-nxp-bsp)"