blob: dea1bdcbb78943dc1478077ce9ed085fd31f79d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
SUMMARY = "Hafnium"
DESCRIPTION = "A reference Secure Partition Manager (SPM) for systems that implement the Armv8.4-A Secure-EL2 extension"
DEPENDS = "gn-native ninja-native bison-native bc-native dtc-native openssl-native"
LICENSE = "BSD-3-Clause & GPL-2.0-only"
LIC_FILES_CHKSUM = "file://LICENSE;md5=782b40c14bad5294672c500501edc103"
PACKAGE_ARCH = "${MACHINE_ARCH}"
CLANGNATIVE = ""
CLANGNATIVE:runtime-llvm = "clang-native"
inherit deploy python3native pkgconfig ${CLANGNATIVE}
SRC_URI = "gitsm://git.trustedfirmware.org/hafnium/hafnium.git;protocol=https;branch=master \
file://0001-arm-hafnium-fix-kernel-tool-linking.patch \
file://0001-Use-pkg-config-native-to-find-the-libssl-headers.patch;patchdir=third_party/linux \
file://0001-work-around-visibility-issue.patch;patchdir=third_party/dtc \
"
SRCREV = "946fde92bedc95e1320684b0bc2dc752bc1e1bc7"
S = "${WORKDIR}/git"
B = "${WORKDIR}/build"
COMPATIBLE_MACHINE ?= "invalid"
COMPATIBLE_MACHINE:qemuarm64 = "qemuarm64"
# Default build 'reference'
HAFNIUM_PROJECT ?= "reference"
# Platform must be set for each machine
HAFNIUM_PLATFORM ?= "invalid"
HAFNIUM_PLATFORM:qemuarm64 = "qemu_aarch64"
# do_deploy will install everything listed in this variable. It is set by
# default to hafnium
HAFNIUM_INSTALL_TARGET ?= "hafnium"
# set project to build
EXTRA_OEMAKE += "PROJECT=${HAFNIUM_PROJECT}"
EXTRA_OEMAKE += "OUT_DIR=${B}"
# Don't use prebuilt binaries for gn and ninja
EXTRA_OEMAKE += "GN=${STAGING_BINDIR_NATIVE}/gn NINJA=${STAGING_BINDIR_NATIVE}/ninja"
do_configure[cleandirs] += "${B}"
do_compile() {
oe_runmake -C ${S}
}
do_install() {
cd ${B}/${HAFNIUM_PLATFORM}_clang
install -d -m 755 ${D}/firmware
for bldfile in ${HAFNIUM_INSTALL_TARGET}; do
install -m 0755 $bldfile.bin $bldfile.elf ${D}/firmware/
done
}
FILES:${PN} = "/firmware/*.bin"
FILES:${PN}-dbg = "/firmware/*.elf"
SYSROOT_DIRS += "/firmware"
INSANE_SKIP:${PN} = "ldflags"
INSANE_SKIP:${PN}-dbg = "ldflags"
# Build paths are currently embedded
INSANE_SKIP:${PN}-dbg += "buildpaths"
do_deploy() {
cp -rf ${D}/firmware/* ${DEPLOYDIR}/
}
addtask deploy after do_install
python() {
# https://developer.trustedfirmware.org/T898
if d.getVar("BUILD_ARCH") != "x86_64":
raise bb.parse.SkipRecipe("Cannot be built on non-x86-64 hosts")
}
EXCLUDE_FROM_WORLD = "1"
|
