blob: 3367df36707f8855f284a2007ee95716c9d73e3e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
FILESEXTRAPATHS:prepend := "${COREBASE}/meta/recipes-extended/ltp/ltp:"
FILESEXTRAPATHS:prepend := "${TITESTBASE}/recipes-extended/ltp/ltp:"
require recipes-extended/ltp/ltp_${PV}.bb
SUMMARY = "Embedded Linux Device Driver Tests based on Linux Test Project"
HOMEPAGE = "https://git.ti.com/cgit/test-automation/ltp-ddt/"
PROVIDES += "ltp"
DEPENDS += "alsa-lib"
PE = "1"
PR = "r7"
PV:append = "+git${SRCPV}"
SRCREV = "a41f17a88403e40ff2646911cde36b630823f14e"
BRANCH ?= "master"
SRC_URI:remove = "git://github.com/linux-test-project/ltp.git;branch=master;protocol=https"
SRC_URI:prepend = "git://git.ti.com/git/test-automation/ltp-ddt.git;protocol=https;branch=${BRANCH} "
SRC_URI:append = " https://git.ti.com/cgit/ti-linux-kernel/ti-linux-kernel/plain/include/uapi/linux/rpmsg_rpc.h?h=ti-linux-5.10.y;name=rpmsg_rpc;subdir=linux;downloadfilename=rpmsg_rpc.h"
SRC_URI[rpmsg_rpc.sha256sum] = "cd237f40a37520a1f2df19fbfeefd00c0a5ad68efeaba9ba0fba60ca16ea09be"
export prefix = "/opt/ltp"
export exec_prefix = "/opt/ltp"
EXTRA_OEMAKE:append = " \
KERNEL_USR_INC=${WORKDIR} \
ALSA_INCPATH=${STAGING_INCDIR} \
ALSA_LIBPATH=${STAGING_LIBDIR} \
"
RDEPENDS:${PN} += "\
acl \
at \
pm-qa \
serialcheck \
memtester \
"
do_install:prepend() {
# Upstream ltp recipe wants to remove this test case in do_install
install -d ${D}${prefix}/runtest/
echo "memcg_stress" >> ${D}${prefix}/runtest/controllers
}
|
