blob: 6bf701bbea9b8beac008e50cf38158ef9ba9998f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
SUMMARY = "Embedded Linux Device Driver Tests based on Linux Test Project"
HOMEPAGE = "http://arago-project.org/git/projects/test-automation/ltp-ddt.git"
SECTION = "console/utils"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
PR = "r0"
PV_append = "+git${SRCPV}"
PROVIDES += "ltp"
DEPENDS = "alsa-lib attr libaio libcap acl openssl zip-native"
RDEPENDS_${PN} = "\
acl \
at \
attr \
bash \
cpio \
cronie \
curl \
e2fsprogs-mke2fs \
expect \
gawk \
gzip \
iproute2 \
ldd \
libaio \
logrotate \
perl \
pm-qa \
python-core \
serialcheck \
unzip \
util-linux \
which \
"
inherit autotools-brokensep
SRCREV = "feec63612a16bb48cd1da698ca794d25ff03bedc"
BRANCH ?= "master"
SRC_URI = "git://arago-project.org/git/projects/test-automation/ltp-ddt.git;branch=${BRANCH} \
file://0003-Add-knob-to-control-tirpc-support.patch \
"
S = "${WORKDIR}/git"
LTPROOT = "/opt/ltp"
# disable TI RPC (Transport-Independent RPC) due to missing dependency
EXTRA_OECONF += " --without-tirpc"
EXTRA_OEMAKE_append = " \
prefix=${LTPROOT} \
CROSS_COMPILE=${HOST_PREFIX} \
SKIP_IDCHECK=1 \
KERNEL_USR_INC=${STAGING_INCDIR} \
ALSA_INCPATH=${STAGING_INCDIR} \
ALSA_LIBPATH=${STAGING_LIBDIR} \
RANLIB=${RANLIB} \
DESTDIR=${D} \
CC='${CC}' \
"
TARGET_CC_ARCH += "${LDFLAGS}"
FILES_${PN}-dbg += " \
${LTPROOT}/.debug \
${LTPROOT}/bin/.debug \
${LTPROOT}/runtest/.debug \
${LTPROOT}/testcases/bin/.debug \
${LTPROOT}/testcases/bin/*/bin/.debug \
${LTPROOT}/testcases/bin/*/test/.debug \
${LTPROOT}/testcases/bin/ddt/.debug \
${LTPROOT}/testcases/bin/ddt/*/bin/.debug \
${LTPROOT}/testcases/bin/ddt/*/test/.debug \
${LTPROOT}/testcases/realtime/*/*/.debug \
"
FILES_${PN}-staticdev += "${LTPROOT}/lib ${LTPROOT}/lib/libmem.a ${LTPROOT}/testcases/data/nm01/lib.a"
FILES_${PN} += "${LTPROOT}/*"
do_install() {
oe_runmake install
}
# Avoid file dependency scans, as LTP checks for things that may or may not
# exist on the running system. For instance it has specific checks for
# csh and ksh which are not typically part of OpenEmbedded systems (but
# can be added via additional layers.)
SKIP_FILEDEPS_${PN} = '1'
|