blob: 6d50c234791a4b1be2cc0eff4e9f0415a15de904 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
SUMMARY = "Xilinx Runtime(XRT) libraries"
DESCRIPTION = "Xilinx Runtime User Space Libraries and headers"
LICENSE = "GPLv2 & Apache-2.0"
LIC_FILES_CHKSUM = "file://../LICENSE;md5=da5408f748bce8a9851dac18e66f4bcf \
file://runtime_src/core/edge/drm/zocl/LICENSE;md5=7d040f51aae6ac6208de74e88a3795f8 \
file://runtime_src/core/pcie/driver/linux/xocl/LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
file://runtime_src/core/pcie/linux/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57 \
file://runtime_src/core/pcie/tools/xbutil/LICENSE;md5=d273d63619c9aeaf15cdaf76422c4f87 \
file://runtime_src/core/edge/tools/xbutil/LICENSE;md5=d273d63619c9aeaf15cdaf76422c4f87 "
BRANCH ?= "2020.1"
REPO ?= "git://github.com/Xilinx/XRT.git;protocol=https"
BRANCHARG = "${@['nobranch=1', 'branch=${BRANCH}'][d.getVar('BRANCH', True) != '']}"
SRC_URI = "${REPO};${BRANCHARG}"
PV = "202010.2.6.0"
SRCREV ?= "2d6bfe4ce91051d4e5b499d38fc493586dd4859a"
S = "${WORKDIR}/git/src"
inherit cmake
BBCLASSEXTEND = "native nativesdk"
# util-linux is for libuuid-dev.
DEPENDS = "libdrm opencl-headers ocl-icd opencl-clhpp boost util-linux git-replacement-native protobuf-native protobuf"
RDEPENDS_${PN} = "bash ocl-icd boost-system boost-filesystem"
EXTRA_OECMAKE += " \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_EXPORT_COMPILE_COMANDS=ON \
"
EXTRA_OECMAKE_append_versal += "-DXRT_AIE_BUILD=true"
TARGET_CXXFLAGS_append_versal += "-DXRT_ENABLE_AIE"
DEPENDS_append_versal += " libmetal libxaiengine"
RDEPENDS_${PN}_append_versal += " libxaiengine"
pkg_postinst_ontarget_${PN}() {
#!/bin/sh
if [ ! -e /etc/OpenCL/vendors/xilinx.icd ]; then
echo "INFO: Creating ICD entry for Xilinx Platform"
mkdir -p /etc/OpenCL/vendors
echo "libxilinxopencl.so" > /etc/OpenCL/vendors/xilinx.icd
chmod -R 755 /etc/OpenCL
fi
}
|
