blob: b7745f2b6bcf8900e23d79dee3dd7f06ddc5933b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
HOMEPAGE = "https://github.com/docker/compose"
SUMMARY = "Multi-container orchestration for Docker"
DESCRIPTION = "Docker compose v2"
DEPENDS = " \
go-md2man \
rsync-native \
"
# Specify the first two important SRCREVs as the format
SRCREV_FORMAT="compose_survey"
SRCREV_compose = "d6f842b042d2f2926901305336527b3eaadf067a"
SRC_URI = "git://github.com/docker/compose;name=compose;branch=main;protocol=https"
include src_uri.inc
# patches and config
SRC_URI += "file://modules.txt"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=175792518e4ac015ab6696d16c4f607e"
GO_IMPORT = "import"
PV = "v2.21.0"
COMPOSE_PKG = "github.com/docker/compose/v2"
inherit go goarch
inherit pkgconfig
COMPATIBLE_HOST = "^(?!mips).*"
do_configure[noexec] = "1"
PACKAGECONFIG ?= "docker-plugin"
PACKAGECONFIG[docker-plugin] = ",,,docker"
include relocation.inc
GOBUILDFLAGS:append = " -mod=vendor"
do_compile() {
cd ${S}/src/import
export GOPATH="$GOPATH:${S}/src/import/.gopath"
# Pass the needed cflags/ldflags so that cgo
# can find the needed headers files and libraries
export GOARCH=${TARGET_GOARCH}
export CGO_ENABLED="1"
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
# our copied .go files are to be used for the build
ln -sf vendor.copy vendor
# inform go that we know what we are doing
cp ${WORKDIR}/modules.txt vendor/
GO_LDFLAGS="-s -w -X internal.Version=${PV} -X ${COMPOSE_PKG}/internal.Version=${PV}"
GO_BUILDTAGS=""
mkdir -p ./bin
${GO} build ${GOBUILDFLAGS} -tags "$GO_BUILDTAGS" -ldflags "$GO_LDFLAGS" -o ./bin/docker-compose ./cmd
}
do_install() {
if ${@bb.utils.contains('PACKAGECONFIG', 'docker-plugin', 'true', 'false', d)}; then
install -d ${D}${nonarch_libdir}/docker/cli-plugins
install -m 755 ${S}/src/import/bin/docker-compose ${D}${nonarch_libdir}/docker/cli-plugins
else
install -d ${D}${bindir}
install -m 755 ${S}/src/import/bin/docker-compose ${D}${bindir}
fi
}
FILES:${PN} += " ${nonarch_libdir}/docker/cli-plugins/"
INHIBIT_PACKAGE_STRIP = "1"
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
