blob: 87619d013865e31d8d618922fece4956073ca5b4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
SUMMARY = "U-boot boot script for Xen on Raspberry Pi 4"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
COMPATIBLE_MACHINE = "^raspberrypi4-64$"
DEPENDS = "u-boot-mkimage-native"
INHIBIT_DEFAULT_DEPS = "1"
SRC_URI = "file://boot.cmd.xen.in"
RPI_DOM0_MEM ??= "256M"
RPI_DEBUG_XEN_ARGS ??= "sync_console bootscrub=0"
do_compile() {
sed -e 's/@@KERNEL_IMAGETYPE@@/${KERNEL_IMAGETYPE}/' \
-e 's/@@KERNEL_BOOTCMD@@/${KERNEL_BOOTCMD}/' \
-e 's/@@RPI_DOM0_MEM@@/${RPI_DOM0_MEM}/' \
-e 's/@@RPI_DEBUG_XEN_ARGS@@/${RPI_DEBUG_XEN_ARGS}/' \
"${WORKDIR}/boot.cmd.xen.in" > "${WORKDIR}/boot.cmd"
mkimage -A ${UBOOT_ARCH} -T script -C none -n "Boot script" -d "${WORKDIR}/boot.cmd" boot.scr
}
inherit kernel-arch deploy nopackages
do_deploy() {
install -d ${DEPLOYDIR}
install -m 0644 boot.scr ${DEPLOYDIR}
}
addtask do_deploy after do_compile before do_build
PROVIDES += "u-boot-default-script"
|
