1 files changed, 74 insertions, 0 deletions
diff --git a/meta-ti-bsp/conf/machine/include/ti43x.inc b/meta-ti-bsp/conf/machine/include/ti43x.inc
new file mode 100644
index 00000000..17ca5240
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/ti43x.inc
@@ -0,0 +1,74 @@
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":ti43x"
+
+DEFAULTTUNE ?= "armv7athf-neon"
+require conf/machine/include/arm/armv7a/tune-cortexa9.inc
+
+# Increase this everytime you change something in the kernel
+MACHINE_KERNEL_PR = "r3"
+
+# Default providers, may need to override for specific machines
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-ti-staging"
+PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot ?= "u-boot-ti-staging"
+
+# Graphics providers and variables
+require conf/machine/include/mesa-pvr.inc
+PREFERRED_PROVIDER_virtual/gpudriver ?= "ti-sgx-ddk-km"
+PVR_DISPLAY_CONTROLLER_ALIAS ?= "omapdrm"
+
+KERNEL_IMAGETYPE = "zImage"
+
+KERNEL_DEVICETREE_PREFIX = " \
+    am437x \
+    am43x \
+    ti/omap/am437x \
+    ti/omap/am43x \
+"
+
+KERNEL_DEVICETREE = " \
+    ti/omap/am437x-gp-evm.dtb \
+    ti/omap/am437x-sk-evm.dtb \
+    ti/omap/am437x-idk-evm.dtb \
+    ti/omap/am43x-epos-evm.dtb \
+"
+
+KERNEL_DEVICETREE += "${@oe.utils.conditional('ENABLE_TI_UIO_DEVICES', '1', 'am437x-idk-pru-excl-uio.dtb', '', d)}"
+
+UBOOT_ARCH = "arm"
+UBOOT_MACHINE = "am43xx_evm_config"
+
+UBOOT_ENTRYPOINT = "0x80008000"
+UBOOT_LOADADDRESS = "0x80008000"
+
+DEVICETREE_FILE = "${@(d.getVar('KERNEL_DEVICETREE') or "").replace("ti/omap/","")}"
+
+# Generate an extlinux.conf file
+UBOOT_EXTLINUX = "1"
+UBOOT_EXTLINUX_ROOT = "root=PARTUUID=${uuid}"
+UBOOT_EXTLINUX_BOOT_FILES = " \
+    extlinux.conf;extlinux/extlinux.conf \
+    ${KERNEL_IMAGETYPE} \
+    ${DEVICETREE_FILE} \
+"
+
+SPL_BINARY = "MLO"
+UBOOT_SUFFIX = "img"
+
+# Use the expected value of the ubifs filesystem's volume name in the kernel
+# and u-boot.
+UBI_VOLNAME = "rootfs"
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
+
+MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "kernel-image-zimage"
+
+MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS += "amx3-cm3 prueth-fw pruhsr-fw pruprp-fw"
+
+# List common SoC features, may need to add touchscreen for specific machines
+MACHINE_FEATURES = "apm usbgadget usbhost vfat ext2 screen alsa gpu"
+
+IMAGE_FSTYPES += "tar.xz wic.xz wic.bmap"
+WKS_FILE ?= "sdimage-2part.wks"
+IMAGE_BOOT_FILES ?= "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} ${UBOOT_EXTLINUX_BOOT_FILES}"
+do_image_wic[depends] += "virtual/bootloader:do_deploy"