1 files changed, 52 insertions, 0 deletions
diff --git a/recipes-bsp/bootfiles/rpi-bootfiles.bb b/recipes-bsp/bootfiles/rpi-bootfiles.bb
new file mode 100644
index 0000000..b04f24b
--- /dev/null
+++ b/recipes-bsp/bootfiles/rpi-bootfiles.bb
@@ -0,0 +1,52 @@
+DESCRIPTION = "Closed source binary files to help boot all raspberry pi devices."
+LICENSE = "Broadcom-RPi"
+
+LIC_FILES_CHKSUM = "file://LICENCE.broadcom;md5=c403841ff2837657b2ed8e5bb474ac8d"
+
+inherit deploy nopackages
+
+RPIFW_DATE ?= "20240319"
+SRCREV = "9f24f4bc2bdd07ffd158cfbb4bce88a2efc4c1f5"
+SHORTREV = "${@d.getVar("SRCREV", False).__str__()[:7]}"
+RPIFW_SRC_URI ?= "https://api.github.com/repos/raspberrypi/firmware/tarball/9f24f4bc2bdd07ffd158cfbb4bce88a2efc4c1f5;downloadfilename=raspberrypi-firmware-${SHORTREV}.tar.gz"
+RPIFW_S ?= "${WORKDIR}/raspberrypi-firmware-${SHORTREV}"
+
+SRC_URI = "${RPIFW_SRC_URI}"
+SRC_URI[sha256sum] = "4b436f8946b139c6a1202375ef55d4848e3bcd8c1a9cb47000e06d7ecec828f7"
+
+PV = "${RPIFW_DATE}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+DEPENDS = "rpi-config rpi-cmdline"
+
+COMPATIBLE_MACHINE = "^rpi$"
+
+S = "${RPIFW_S}/boot"
+
+PR = "r3"
+
+do_deploy() {
+    install -d ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
+
+    for i in ${S}/*.elf ; do
+        cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
+    done
+    for i in ${S}/*.dat ; do
+        cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
+    done
+    for i in ${S}/*.bin ; do
+        cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
+    done
+
+    # Add stamp in deploy directory
+    touch ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}/${PN}-${PV}.stamp
+}
+
+do_deploy[depends] += "rpi-config:do_deploy rpi-cmdline:do_deploy"
+
+addtask deploy before do_build after do_install
+do_deploy[dirs] += "${DEPLOYDIR}/${BOOTFILES_DIR_NAME}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+