1 files changed, 41 insertions, 0 deletions
diff --git a/recipes-devtools/cctools-port/cctools-port-crosssdk_973.0.1.bb b/recipes-devtools/cctools-port/cctools-port-crosssdk_973.0.1.bb
new file mode 100644
index 0000000..4082150
--- /dev/null
+++ b/recipes-devtools/cctools-port/cctools-port-crosssdk_973.0.1.bb
@@ -0,0 +1,41 @@
+DESCRIPTION = "Linux port of Apple CCTools"
+SECTION = "devel"
+LICENSE = "ApplePSLicense-2.0"
+LIC_FILES_CHKSUM = "file://cctools/APPLE_LICENSE;md5=dacaafbaf91483700da837d31213a1e8"
+
+SRCREV = "f28fb5e9c31efd3d0552afcce2d2c03cae25c1ca"
+SRC_URI = "git://github.com/tpoechtrager/cctools-port.git;branch=master;protocol=https"
+
+PR = "r2"
+
+inherit autotools crosssdk
+
+DEPENDS += "util-linux-native openssl-native xar-native libtapi-native"
+PROVIDES = "virtual/${TARGET_PREFIX}binutils-crosssdk"
+
+DEPENDS += "clang-native libcxx-native"
+
+TOOLCHAIN:class-crosssdk = "clang"
+COMPILER_RT:class-crosssdk = "-rtlib=libgcc --unwindlib=libgcc"
+LIBCPLUSPLUS:class-crosssdk = "-stdlib=libc++ -lc++abi"
+
+EXTRA_OECONF:append = " \
+    --with-llvm-config=${STAGING_DIR_NATIVE}/usr/bin/llvm-config \
+    --enable-lto-support \
+    --enable-xar-support \
+    --with-libxar=${STAGING_DIR_NATIVE}/usr \
+    --enable-tapi-support \
+    --with-libtapi=${STAGING_DIR_NATIVE}/usr \
+"
+
+S = "${WORKDIR}/git"
+B = "${WORKDIR}/build"
+
+AUTOTOOLS_SCRIPT_PATH = "${S}/cctools"
+
+do_configure:prepend() {
+    PWD_CUR=$(pwd)
+    cd ${AUTOTOOLS_SCRIPT_PATH}
+    libtoolize
+    cd ${PWD_CUR}
+}