summaryrefslogtreecommitdiffstats
path: root/meta/recipes-rt/rt-tests/rt-tests_git.bb
blob: 89e3323b69e022d0199367c60dee5cd9de181db9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
SUMMARY = "Real-Time preemption testcases"
HOMEPAGE = "https://wiki.linuxfoundation.org/realtime/documentation/start"
DESCRIPTION = "The main aim of the PREEMPT_RT patch is to minimize the amount of kernel code that is non-preemptible Therefore several substitution mechanisms and new mechanisms are implemented."
SECTION = "tests"
DEPENDS = "linux-libc-headers virtual/libc numactl"
LICENSE = "GPLv2 & GPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"

require rt-tests.inc
inherit ptest

SRC_URI += " \
            file://run-ptest \
            file://rt_bmark.py \
            file://0001-Makefile-Allow-for-CC-and-AR-to-be-overridden.patch \
           "

# rt-tests needs PI mutex support in libc
COMPATIBLE_HOST_libc-musl = 'null'

# Do not install hwlatdetect
EXTRA_OEMAKE += "PYLIB=''"

do_install() {
        oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} \
                           INCLUDEDIR=${includedir}
}

do_install_ptest() {
        cp ${WORKDIR}/rt_bmark.py ${D}${PTEST_PATH}
}

RDEPENDS_${PN}-ptest += " stress-ng python3 python3-multiprocessing python3-datetime python3-misc"

FILES_${PN} += "${prefix}/src/backfire"
RDEPENDS_${PN} += "bash"