blob: 7dc59d9fe76b1d7489ab6f1f4fea4db0f433f9fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
require automake.inc
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
DEPENDS_class-native = "autoconf-native"
NAMEVER = "${@oe.utils.trim_version("${PV}", 2)}"
RDEPENDS_${PN} += "\
autoconf \
perl \
perl-module-bytes \
perl-module-data-dumper \
perl-module-strict \
perl-module-text-parsewords \
perl-module-thread-queue \
perl-module-threads \
perl-module-vars "
RDEPENDS_${PN}_class-native = "autoconf-native hostperl-runtime-native"
SRC_URI += "file://python-libdir.patch \
file://buildtest.patch \
file://performance.patch \
file://new_rt_path_for_test-driver.patch \
file://0001-automake-Add-default-libtool_tag-to-cppasm.patch \
file://0001-build-fix-race-in-parallel-builds.patch \
"
SRC_URI[sha256sum] = "ce010788b51f64511a1e9bb2a1ec626037c6d0e7ede32c1c103611b9d3cba65f"
PERL = "${USRBINPATH}/perl"
PERL_class-native = "${USRBINPATH}/env perl"
PERL_class-nativesdk = "${USRBINPATH}/env perl"
CACHED_CONFIGUREVARS += "ac_cv_path_PERL='${PERL}'"
do_install_append () {
install -d ${D}${datadir}
}
BBCLASSEXTEND = "native nativesdk"
|
