summaryrefslogtreecommitdiffstats
path: root/meta/recipes-connectivity/libnss-mdns/libnss-mdns_0.15.1.bb
blob: e455a60bd5ec2443370ac1cb79f9c99e3d6984c5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
SUMMARY = "Name Service Switch module for Multicast DNS (zeroconf) name resolution"
HOMEPAGE = "https://github.com/lathiat/nss-mdns"
DESCRIPTION = "nss-mdns is a plugin for the GNU Name Service Switch (NSS) functionality of the GNU C Library (glibc) providing host name resolution via Multicast DNS (aka Zeroconf, aka Apple Rendezvous, aka Apple Bonjour), effectively allowing name resolution by common Unix/Linux programs in the ad-hoc mDNS domain .local."
SECTION = "libs"

LICENSE = "LGPLv2.1+"
LIC_FILES_CHKSUM = "file://LICENSE;md5=2d5025d4aa3495befef8f17206a5b0a1"

DEPENDS = "avahi"

SRC_URI = "git://github.com/lathiat/nss-mdns \
           "

SRCREV = "4b3cfe818bf72d99a02b8ca8b8813cb2d6b40633"

S = "${WORKDIR}/git"

inherit autotools pkgconfig

COMPATIBLE_HOST:libc-musl = 'null'

EXTRA_OECONF = "--libdir=${base_libdir}"

RDEPENDS:${PN} = "avahi-daemon"

pkg_postinst:${PN} () {
	sed '
		/^hosts:/ !b
		/\<mdns\(4\|6\)\?\(_minimal\)\?\>/ b
		s/\([[:blank:]]\+\)dns\>/\1mdns4_minimal [NOTFOUND=return] dns/g
		' -i $D${sysconfdir}/nsswitch.conf
}

pkg_prerm:${PN} () {
	sed '
		/^hosts:/ !b
		s/[[:blank:]]\+mdns\(4\|6\)\?\(_minimal\( \[NOTFOUND=return\]\)\?\)\?//g
		' -i $D${sysconfdir}/nsswitch.conf
}