summaryrefslogtreecommitdiffstats
path: root/meta/classes/scons.bbclass
blob: 9ee7d1587d7b78fc914c9bb014448f019568e8bb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
DEPENDS += "python-scons-native"

EXTRA_OESCONS ?= ""

do_configure() {
	if [ -n "${CONFIGURESTAMPFILE}" ]; then
		if [ -e "${CONFIGURESTAMPFILE}" -a "`cat ${CONFIGURESTAMPFILE}`" != "${BB_TASKHASH}" -a "${CLEANBROKEN}" != "1" ]; then
			${STAGING_BINDIR_NATIVE}/scons --clean PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS}
		fi

		mkdir -p `dirname ${CONFIGURESTAMPFILE}`
		echo ${BB_TASKHASH} > ${CONFIGURESTAMPFILE}
	fi
}

scons_do_compile() {
	${STAGING_BINDIR_NATIVE}/scons ${PARALLEL_MAKE} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} || \
	die "scons build execution failed."
}

scons_do_install() {
	${STAGING_BINDIR_NATIVE}/scons install_root=${D}${prefix} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} install || \
	die "scons install execution failed."
}

EXPORT_FUNCTIONS do_compile do_install