aboutsummaryrefslogtreecommitdiffstats
path: root/dynamic-layers/rk-rauc-demo/recipes-bsp/u-boot/u-boot_%.bbappend
blob: fa96b4dd18bf8814cf1eefcbb784d99cc87caccc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
inherit rk-rauc-demo-features-check

FILESEXTRAPATHS:prepend:rk-rauc-demo := "${THISDIR}/files:"

DEPENDS:append:rk-rauc-demo = " u-boot-mkimage-native"
SRC_URI:append:rk-rauc-demo = " \
	file://uboot-rauc.cfg \
	file://boot.cmd.in \
	"

do_compile:append:rk-rauc-demo() {
	# create boot script
	sed -e 's|@@KERNEL_BOOTFILE@@|${UBOOT_EXTLINUX_KERNEL_IMAGE}|' \
	    "${UNPACKDIR}/boot.cmd.in" > "${UNPACKDIR}/boot.cmd"
	mkimage -A ${UBOOT_ARCH} -T script -C none -n "Boot script" -d "${UNPACKDIR}/boot.cmd" ${UNPACKDIR}/boot.scr

	# tweak environment
	echo "bootmeths=script extlinux" >> ${B}/u-boot-initial-env
	echo "bootargsbase=${UBOOT_EXTLINUX_KERNEL_ARGS} ${UBOOT_EXTLINUX_CONSOLE}" >> ${B}/u-boot-initial-env
}

do_install:append:rk-rauc-demo() {
	install -d ${D}/boot
	install -m 0644 ${UNPACKDIR}/boot.scr ${D}/boot
}
FILES:${PN}-extlinux += "/boot/boot.scr"