aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-graphics/mesa/mesa_git.bb
blob: d902e8e02390f9472ae8f5f850044f73dac57063 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
require recipes-graphics/mesa/mesa.inc

SRC_URI = "git://gitlab.freedesktop.org/mesa/mesa.git;protocol=https \
           file://0001-meson.build-check-for-all-linux-host_os-combinations.patch \
           file://0002-meson.build-make-TLS-ELF-optional.patch \
           file://0003-Allow-enable-DRI-without-DRI-drivers.patch \
           file://0004-Revert-mesa-Enable-asm-unconditionally-now-that-gen_.patch \
           file://0001-meson-misdetects-64bit-atomics-on-mips-clang.patch \
           "
LIC_FILES_CHKSUM = "file://docs/license.rst;md5=17a4ea65de7a9ab42437f3131e616a7f"

SRCREV = "${@oe.utils.conditional("MESA_DEV", "1", "${AUTOREV}", "a084d012a9ee71049749a6209b0a1cd637e113e1", d)}"
DEFAULT_PREFERENCE = "${@oe.utils.conditional("MESA_DEV", "1", "1", "-1", d)}"

PLATFORMS_remove = "drm surfaceless"
PACKAGECONFIG[osmesa] = "-Dosmesa=true,-Dosmesa=false"
DRIDRIVERS_remove = "swrast"
DRIDRIVERS_class-native = "auto"
DRIDRIVERS_class-nativesdk = "auto"

S = "${WORKDIR}/git"
PV = "20.4-dev+git${SRCPV}"
ERROR_QA_remove = "version-going-backwards"

# Add package to install require files to run tests for mesa
PACKAGES =+ "mesa-ci"
FILES_${PN}-ci = "${bindir}/deqp-runner.sh ${datadir}/mesa/deqp-*"
do_install_append () {
    install -d ${D}/${datadir}/mesa

    install -m 0644 ${S}/.gitlab-ci/deqp-default-skips.txt ${D}/${datadir}/mesa/
    for f in ${S}/src/freedreno/ci/deqp-freedreno-*; do
        install -m 0644 $f ${D}/${datadir}/mesa/
    done

    install -d ${D}/${bindir}
    install -m 0755 ${S}/.gitlab-ci/deqp-runner.sh ${D}/${bindir}/
}