#@TYPE: Machine
#@NAME: NXP i.MX6UL Evaluation Kit
#@SOC: i.MX6UL
#@DESCRIPTION: Machine configuration for NXP i.MX6UL EVK
#@MAINTAINER: Alexandru Palalau <ioan-alexandru.palalau@nxp.com>

MACHINEOVERRIDES =. "mx6:mx6ul:"

include conf/machine/include/imx-base.inc
include conf/machine/include/tune-cortexa7.inc

MACHINE_FEATURES += "wifi bluetooth bcm4339 bcm43455"

KERNEL_DEVICETREE = " \
	imx6ul-14x14-evk-btwifi.dtb \
	imx6ul-14x14-evk-btwifi-oob.dtb \
	imx6ul-14x14-evk-csi.dtb \
	imx6ul-14x14-evk.dtb \
	imx6ul-14x14-evk-ecspi.dtb \
	imx6ul-14x14-evk-ecspi-slave.dtb \
	imx6ul-14x14-evk-emmc.dtb \
	imx6ul-14x14-evk-gpmi-weim.dtb \
"
KERNEL_DEVICETREE_use-mainline-bsp = "imx6ul-14x14-evk.dtb"

# These u-boot variables default to the correct settings for u-boot-imx.
# Set overrides for u-boot-fslc.
UBOOT_MAKE_TARGET_pn-u-boot-fslc = ""
UBOOT_SUFFIX_pn-u-boot-fslc = "img"
SPL_BINARY_pn-u-boot-fslc = "SPL"
WKS_FILE_pn-u-boot-fslc = "imx-uboot-spl-bootpart.wks.in"

UBOOT_CONFIG ??= " \
    sd \
    ${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'sd-optee', '', d)} \
"
UBOOT_CONFIG[sd]       = "mx6ul_14x14_evk_config,sdcard"
UBOOT_CONFIG[sd-optee] = "mx6ul_14x14_evk_optee_config,sdcard"
UBOOT_CONFIG[emmc]     = "mx6ul_14x14_evk_emmc_config,sdcard"
UBOOT_CONFIG[qspi1]    = "mx6ul_14x14_evk_qspi1_config"
UBOOT_CONFIG[mfgtool]  = "mx6ul_14x14_evk_config"

OPTEE_BIN_EXT = "6ulevk"