#@TYPE: Machine
#@NAME: NXP i.MX6QP/Q/DL SABRE Automotive
#@SOC: i.MX6QP/Q/DL
#@DESCRIPTION: Machine configuration for NXP i.MX6QP/Q/DL SABRE Automotive
#@MAINTAINER: Daiane Angolini <daiane.angolini@nxp.com>
#
# This machine replaces the following machines:
#    * imx6qpsabreauto
#    * imx6qsabreauto
#    * imx6dlsabreauto
#    * imx6solosabreauto
# and is able to work for all the machines.

MACHINEOVERRIDES =. "mx6:mx6q:mx6dl:"

require conf/machine/include/imx-base.inc
require conf/machine/include/tune-cortexa9.inc

KERNEL_DEVICETREE = " \
    imx6qp-sabreauto.dtb imx6qp-sabreauto-ecspi.dtb imx6qp-sabreauto-flexcan1.dtb \
    imx6qp-sabreauto-gpmi-weim.dtb \
    \
    imx6q-sabreauto.dtb imx6q-sabreauto-gpmi-weim.dtb imx6q-sabreauto-ecspi.dtb \
    imx6q-sabreauto-flexcan1.dtb imx6q-sabreauto-enetirq.dtb \
    \
    imx6dl-sabreauto.dtb imx6dl-sabreauto-gpmi-weim.dtb imx6dl-sabreauto-ecspi.dtb \
    imx6dl-sabreauto-flexcan1.dtb imx6dl-sabreauto-enetirq.dtb \
"
KERNEL_DEVICETREE_use-mainline-bsp = " \
    imx6qp-sabreauto.dtb \
    imx6q-sabreauto.dtb \
    imx6dl-sabreauto.dtb \
"

### u-boot-fslc settings ###

SPL_BINARY_pn-u-boot-fslc = "SPL"
UBOOT_MACHINE_pn-u-boot-fslc ?= "mx6sabreauto_defconfig"
UBOOT_SUFFIX_pn-u-boot-fslc = "img"

### u-boot-imx settings ###

# The u-boot-imx does not provide unified functionality for DL/Q/QP SoC
# variants. Change the defconfig to the targeted SoC variant.
SPL_BINARY_pn-u-boot-imx = ""
UBOOT_MACHINE_pn-u-boot-imx = "mx6qsabreauto_defconfig"
UBOOT_MAKE_TARGET_pn-u-boot-imx = "u-boot.imx"
UBOOT_SUFFIX_pn-u-boot-imx = "imx"

WKS_FILE = " \
    ${@bb.utils.contains('IMX_DEFAULT_BOOTLOADER', \
                         'u-boot-fslc', 'imx-uboot-spl-bootpart.wks.in', \
                                        'imx-uboot-bootpart.wks.in', d)}"

SERIAL_CONSOLES = "115200;ttymxc3"

MACHINE_FIRMWARE_append_mx6 = " linux-firmware-ath6k"

MACHINE_FEATURES += " pci wifi bluetooth"