aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-support/spice/spice_git.bb
blob: 478813ce7767eb3b4336f52aba7e9d7bf3992fce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
#
# Copyright (C) 2013 Wind River Systems, Inc.
#

SUMMARY = "Simple Protocol for Independent Computing Environments"
DESCRIPTION = "SPICE (the Simple Protocol for Independent Computing \
Environments) is a remote-display system built for virtual \
environments which allows users to view a computing 'desktop' \ 
environment - not only on its computer-server machine, but also from \
anywhere on the Internet and using a wide variety of machine \
architectures."

LICENSE = "BSD & LGPLv2.1+"
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"

PR = "r0"
PV = "0.12.4"

# Actual versions based on the checkouts below
# spice = "0.12.4"
# common = "0.12.6"
# protocol = "0.12.6"
SRCREV_spice = "b270fb010a3ddb432dfe6b15e4bdffa6ac086cd0"
SRCREV_spice-common = "fe93908238196bd632287fc9875e6f2e11105d04"
SRCREV_spice-protocol = "784407f248e7f99d2bfcc9368f9acd1efb2b9617"

SRCREV_FORMAT = "spice_spice-common_spice-protocol"

SRC_URI = "git://anongit.freedesktop.org/spice/spice;name=spice;branch=master \
           git://anongit.freedesktop.org/spice/spice-common;destsuffix=git/spice-common;name=spice-common;branch=master \
           git://anongit.freedesktop.org/spice/spice-protocol;destsuffix=git/spice-common/spice-protocol;name=spice-protocol;branch=master \
          "

SRC_URI += " \
        file://spice-fix-CVE-2013-4282.patch \
        file://configure.ac-add-subdir-objects-to-AM_INIT_AUTOMAKE.patch \
        file://build-allow-separated-src-and-build-dirs.patch \
        file://0001-red_parse_qxl-Fix-BITMAP_FMT_IS_RGB-defined-but-not-.patch \
        file://0001-Use-PRI-macros-in-printf-to-keep-compatibility-betwe.patch \
        file://Fix-build-issues-with-gcc-7.patch \
        file://CVE-2017-7506-1.patch \
        file://CVE-2017-7506-2.patch \
        file://CVE-2017-7506-3.patch \
        "

S = "${WORKDIR}/git"

inherit autotools gettext python3native python3-dir pkgconfig

DEPENDS += "python3-native celt051 python3-pyparsing jpeg pixman alsa-lib glib-2.0"

export PYTHON="${STAGING_BINDIR_NATIVE}/python-native/python"
export PYTHONPATH="${PKG_CONFIG_SYSROOT_DIR}${libdir}/python${PYTHON_BASEVERSION}/site-packages"

PACKAGECONFIG ?= "sasl"

PACKAGECONFIG[smartcard] = "--enable-smartcard,--disable-smartcard,libcacard,"
PACKAGECONFIG[sasl] = "--with-sasl,--without-sasl,cyrus-sasl,"
PACKAGECONFIG[client] = "--enable-client,--disable-client,,"
PACKAGECONFIG[gui] = "--enable-gui,--disable-gui,,"
PACKAGECONFIG[opengl] = "--enable-opengl,--disable-opengl,,"
PACKAGECONFIG[xinerama] = "--enable-xinerama,--disable-xinerama,libxinerama,"

PACKAGES =+ "${PN}-protocol"
LICENSE:${PN}-protocol = "BSD"
FILES:${PN}-protocol += "${includedir}/spice-1"
FILES:${PN}-protocol += "${datadir}/pkgconfig"

do_configure:prepend() {
	mkdir -p ${S}/spice-common/spice-protocol/m4
}

do_install:append() {
	cd ${B}/spice-common/spice-protocol
	oe_runmake DESTDIR="${D}" install
	cd -
}

COMPATIBLE_HOST = '(x86_64|i.86).*-linux'