blob: 7b3bb284b521bb6cd210553198b35df81bd78974 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
|
DESCRIPTION = "OpenStack Block storage service"
HOMEPAGE = "https://launchpad.net/cinder"
SECTION = "devel/python"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=1dece7821bf3fd70fe1309eaa37d52a2"
PR = "r0"
SRCNAME = "cinder"
SRC_URI = "git://github.com/openstack/${SRCNAME}.git;branch=stable/havana \
file://cinder.conf \
file://cinder.init \
file://cinder-volume \
file://0001-run_tests-respect-tools-dir.patch \
file://nfs_setup.sh \
file://glusterfs_setup.sh \
file://lvm_iscsi_setup.sh \
file://add-cinder-volume-types.sh \
file://fix_cinder_memory_leak.patch \
file://cinder-builtin-tests-config-location.patch \
"
SRCREV="81259f36f57e91b31009fbd209ea2a07a2ceb213"
PV="2013.2.3+git${SRCPV}"
S = "${WORKDIR}/git"
inherit setuptools update-rc.d identity default_configs
CINDER_BACKUP_BACKEND_DRIVER ?= "cinder.backup.drivers.swift"
do_install_prepend() {
sed 's:%PYTHON_SITEPACKAGES_DIR%:${PYTHON_SITEPACKAGES_DIR}:g' -i ${S}/${SRCNAME}/tests/conf_fixture.py
sed 's:%PYTHON_SITEPACKAGES_DIR%:${PYTHON_SITEPACKAGES_DIR}:g' -i ${S}/${SRCNAME}/tests/fake_flags.py
}
do_install_append() {
TEMPLATE_CONF_DIR=${S}${sysconfdir}/${SRCNAME}
CINDER_CONF_DIR=${D}${sysconfdir}/${SRCNAME}
sed -e "s:%SERVICE_TENANT_NAME%:${SERVICE_TENANT_NAME}:g" \
${TEMPLATE_CONF_DIR}/api-paste.ini > ${WORKDIR}/api-paste.ini
sed -e "s:%SERVICE_USER%:${SRCNAME}:g" -i ${WORKDIR}/api-paste.ini
sed -e "s:%SERVICE_PASSWORD%:${SERVICE_PASSWORD}:g" \
-i ${WORKDIR}/api-paste.ini
sed -e "s:%DB_USER%:${DB_USER}:g" -i ${WORKDIR}/cinder.conf
sed -e "s:%DB_PASSWORD%:${DB_PASSWORD}:g" -i ${WORKDIR}/cinder.conf
sed -e "s:%CINDER_BACKUP_BACKEND_DRIVER%:${CINDER_BACKUP_BACKEND_DRIVER}:g" -i ${WORKDIR}/cinder.conf
install -d ${CINDER_CONF_DIR}
install -m 600 ${WORKDIR}/cinder.conf ${CINDER_CONF_DIR}/
install -m 600 ${WORKDIR}/api-paste.ini ${CINDER_CONF_DIR}/
install -m 600 ${S}/etc/cinder/policy.json ${CINDER_CONF_DIR}/
install -d ${CINDER_CONF_DIR}/drivers
install -m 600 ${WORKDIR}/nfs_setup.sh ${CINDER_CONF_DIR}/drivers/
install -m 600 ${WORKDIR}/glusterfs_setup.sh ${CINDER_CONF_DIR}/drivers/
install -m 600 ${WORKDIR}/lvm_iscsi_setup.sh ${CINDER_CONF_DIR}/drivers/
install -m 700 ${WORKDIR}/add-cinder-volume-types.sh ${CINDER_CONF_DIR}/
install -d ${D}${localstatedir}/log/${SRCNAME}
if ${@base_contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
install -d ${D}${sysconfdir}/init.d
sed 's:@suffix@:api:' < ${WORKDIR}/cinder.init >${WORKDIR}/cinder-api.init.sh
install -m 0755 ${WORKDIR}/cinder-api.init.sh ${D}${sysconfdir}/init.d/cinder-api
sed 's:@suffix@:scheduler:' < ${WORKDIR}/cinder.init >${WORKDIR}/cinder-scheduler.init.sh
install -m 0755 ${WORKDIR}/cinder-scheduler.init.sh ${D}${sysconfdir}/init.d/cinder-scheduler
sed 's:@suffix@:backup:' < ${WORKDIR}/cinder.init >${WORKDIR}/cinder-backup.init.sh
install -m 0755 ${WORKDIR}/cinder-backup.init.sh ${D}${sysconfdir}/init.d/cinder-backup
install -m 0755 ${WORKDIR}/cinder-volume ${D}${sysconfdir}/init.d/cinder-volume
fi
# test setup
cp run_tests.sh ${CINDER_CONF_DIR}
cp -r tools ${CINDER_CONF_DIR}
}
CINDER_LVM_VOLUME_BACKING_FILE_SIZE ?= "2G"
CINDER_NFS_VOLUME_SERVERS_DEFAULT = "controller:/etc/cinder/nfs_volumes"
CINDER_NFS_VOLUME_SERVERS ?= "${CINDER_NFS_VOLUME_SERVERS_DEFAULT}"
CINDER_GLUSTERFS_VOLUME_SERVERS_DEFAULT = "controller:/glusterfs_volumes"
CINDER_GLUSTERFS_VOLUME_SERVERS ?= "${CINDER_GLUSTERFS_VOLUME_SERVERS_DEFAULT}"
pkg_postinst_${SRCNAME}-setup () {
if [ "x$D" != "x" ]; then
exit 1
fi
# This is to make sure postgres is configured and running
if ! pidof postmaster > /dev/null; then
/etc/init.d/postgresql-init
/etc/init.d/postgresql start
fi
if [ ! -d /var/log/cinder ]; then
mkdir /var/log/cinder
fi
sudo -u postgres createdb cinder
cinder-manage db sync
#Create cinder volume group backing file
sed 's/%CINDER_LVM_VOLUME_BACKING_FILE_SIZE%/${CINDER_LVM_VOLUME_BACKING_FILE_SIZE}/g' -i /etc/cinder/drivers/lvm_iscsi_setup.sh
echo "include /etc/cinder/data/volumes/*" >> /etc/tgt/targets.conf
# Create Cinder nfs_share config file with default nfs server
if [ ! -f /etc/cinder/nfs_shares ]; then
echo "${CINDER_NFS_VOLUME_SERVERS}" > /etc/cinder/nfs_shares
sed 's/\s\+/\n/g' -i /etc/cinder/nfs_shares
[[ "x${CINDER_NFS_VOLUME_SERVERS}" == "x${CINDER_NFS_VOLUME_SERVERS_DEFAULT}" ]] && is_default="1" || is_default="0"
/bin/bash /etc/cinder/drivers/nfs_setup.sh ${is_default}
fi
# Create Cinder glusterfs_share config file with default glusterfs server
if [ ! -f /etc/cinder/glusterfs_shares ] && [ -f /usr/sbin/glusterfsd ]; then
echo "${CINDER_GLUSTERFS_VOLUME_SERVERS}" > /etc/cinder/glusterfs_shares
sed 's/\s\+/\n/g' -i /etc/cinder/glusterfs_shares
[[ "x${CINDER_GLUSTERFS_VOLUME_SERVERS}" == "x${CINDER_GLUSTERFS_VOLUME_SERVERS_DEFAULT}" ]] && is_default="1" || is_default="0"
/bin/bash /etc/cinder/drivers/glusterfs_setup.sh ${is_default}
fi
}
PACKAGES += "${SRCNAME}-tests ${SRCNAME} ${SRCNAME}-setup ${SRCNAME}-api ${SRCNAME}-volume ${SRCNAME}-scheduler ${SRCNAME}-backup"
ALLOW_EMPTY_${SRCNAME}-setup = "1"
FILES_${PN} = "${libdir}/*"
FILES_${SRCNAME}-tests = "${sysconfdir}/${SRCNAME}/run_tests.sh \
${sysconfdir}/${SRCNAME}/tools"
FILES_${SRCNAME}-api = "${bindir}/cinder-api \
${sysconfdir}/init.d/cinder-api"
FILES_${SRCNAME}-volume = "${bindir}/cinder-volume \
${sysconfdir}/init.d/cinder-volume"
FILES_${SRCNAME}-scheduler = "${bindir}/cinder-scheduler \
${sysconfdir}/init.d/cinder-scheduler"
FILES_${SRCNAME}-backup = "${bindir}/cinder-backup \
${sysconfdir}/init.d/cinder-backup"
FILES_${SRCNAME} = "${bindir}/* \
${sysconfdir}/${SRCNAME}/* \
${localstatedir}/* \
${sysconfdir}/${SRCNAME}/drivers/* \
"
DEPENDS += " \
python-pip \
python-pbr \
"
RDEPENDS_${PN} += "lvm2 \
python-sqlalchemy \
python-amqplib \
python-anyjson \
python-eventlet \
python-kombu \
python-lxml \
python-routes \
python-webob \
python-greenlet \
python-lockfile \
python-pastedeploy \
python-paste \
python-sqlalchemy-migrate \
python-stevedore \
python-suds \
python-paramiko \
python-babel \
python-iso8601 \
python-setuptools-git \
python-glanceclient \
python-keystoneclient \
python-swiftclient \
python-cinderclient \
python-oslo.config \
python-pbr \
"
RDEPENDS_${SRCNAME} = "${PN} \
postgresql postgresql-client python-psycopg2 tgt"
RDEPENDS_${SRCNAME}-api = "${SRCNAME}"
RDEPENDS_${SRCNAME}-volume = "${SRCNAME}"
RDEPENDS_${SRCNAME}-scheduler = "${SRCNAME}"
RDEPENDS_${SRCNAME}-setup = "postgresql sudo ${SRCNAME}"
INITSCRIPT_PACKAGES = "${SRCNAME}-api ${SRCNAME}-volume ${SRCNAME}-scheduler ${SRCNAME}-backup"
INITSCRIPT_NAME_${SRCNAME}-api = "cinder-api"
INITSCRIPT_PARAMS_${SRCNAME}-api = "${OS_DEFAULT_INITSCRIPT_PARAMS}"
INITSCRIPT_NAME_${SRCNAME}-volume = "cinder-volume"
INITSCRIPT_PARAMS_${SRCNAME}-volume = "${OS_DEFAULT_INITSCRIPT_PARAMS}"
INITSCRIPT_NAME_${SRCNAME}-scheduler = "cinder-scheduler"
INITSCRIPT_PARAMS_${SRCNAME}-scheduler = "${OS_DEFAULT_INITSCRIPT_PARAMS}"
INITSCRIPT_NAME_${SRCNAME}-backup = "cinder-backup"
INITSCRIPT_PARAMS_${SRCNAME}-backup = "${OS_DEFAULT_INITSCRIPT_PARAMS}"
|
