aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-qt4/qt4/qt4-4.8.7.inc
blob: dfd681c91bf7651d353389fafe231ae6d5b8c1b0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
LICENSE = "LGPLv2.1 | GPLv3"
LIC_FILES_CHKSUM = "file://LICENSE.LGPL;md5=fbc093901857fcd118f065f900982c24 \
                    file://LICENSE.GPL3;md5=6e1694ee338db410417517884918d4d2 \
                    file://LGPL_EXCEPTION.txt;md5=0145c4d1b6f96a661c2c139dfb268fb6"

FILESEXTRAPATHS =. "${FILE_DIRNAME}/qt4-${PV}:"

SRC_URI = "http://download.qt-project.org/archive/qt/4.8/${PV}/qt-everywhere-opensource-src-${PV}.tar.gz \
           file://0003-webkit2-set-OUTPUT_DIR-value-if-empty.patch \
           file://0004-configure-qmake-is-already-built-in-qt4-tools-native.patch \
           file://0008-qmake.pro-Allow-building-a-separate-qmake-for-the-ta.patch \
           file://0009-qmake-fix-source-file-references-in-qmake.pri.patch \
           file://0010-configure-Hack-to-not-use-the-pg_config-of-the-host-.patch \
           file://0011-freetype-host-includes.patch \
           file://0012-Add-2bpp-support.patch \
           file://0013-configure-add-crossarch-option.patch \
           file://0014-translations-fix-phony-translation-linking-error.patch \
           file://0015-configure-add-nostrip-for-debug-packages.patch \
           file://0016-configure-eval-QMAKE_CXX.patch \
           file://0017-configure-ensure-we-identify-the-compiler-as-g-in-co.patch \
           file://0018-configure-make-pulseaudio-a-configurable-option.patch \
           file://0019-Fixes-for-gcc-4.7.0-particularly-on-qemux86.patch \
           file://0027-tools.pro-disable-qmeegographicssystemhelper.patch \
           file://0030-aarch64_arm64_qatomic_support.patch \
           file://0031-aarch64_arm64_mkspecs.patch \
           file://0032-aarch64_add_header.patch \
           file://0034-Fix-kmap2qmap-build-with-clang.patch \
           file://0035-Add-nios2-support.patch \
           file://0036-qt-everywhere-opensource-src-4.8.7-gcc6.patch \
           file://0037-fix-configure-with-icu60.patch \
           file://0038-prevent-gcc-9.2-miscompiling-Q_FOREACH.patch \
           file://0039-silence-some-loud-but-innocent-warnings.patch \
           file://gcc-version.patch \
           file://Fix-QWSLock-invalid-argument-logs.patch \
           file://add_check_for_aarch64_32.patch \
           file://0001-QWS-fix-24-bit-RGB-BGR-handling.patch \
           file://g++.conf \
           file://linux.conf \
           file://fix-for-mips-n32.patch \
           file://qt-everywhere-opensource-src-4.8.6-QTBUG-22829.patch \
           "

SRC_URI[md5sum] = "d990ee66bf7ab0c785589776f35ba6ad"
SRC_URI[sha256sum] = "e2882295097e47fe089f8ac741a95fef47e0a73a3f3cdf21b56990638f626ea0"

UPSTREAM_CHECK_URI = "http://download.qt.io/archive/qt/4.8/"
UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)/"

S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"

# workaround for class std::auto_ptr' is deprecated with gcc-6
CXXFLAGS += "-Wno-deprecated -DUCHAR_TYPE=wchar_t"

# disable webkit for mips64 n32 temporarily that fails to compile,
# qt upstream defect:
# https://bugreports.qt-project.org/browse/QTBUG-39224
QT_CONFIG_FLAGS_append_mips64n32 = " -no-webkit"

# disable webkit for aarch64 temporarily that fails to compile
QT_CONFIG_FLAGS_append_aarch64 = " -no-webkit"

FILES_${QT_BASE_NAME}-tools_append     = " ${bindir}/qml ${bindir}/qmlplugindump"
FILES_${QT_BASE_NAME}-tools-dbg_append = " ${bindir}/.debug/qml ${bindir}/.debug/qmlplugindump"

PACKAGES_append = " ${QT_BASE_NAME}-tests-dbg ${QT_BASE_NAME}-tests"
FILES_${QT_BASE_NAME}-tests-dbg        = "${prefix}/tests/qt4/*/.debug"
FILES_${QT_BASE_NAME}-tests            = "${prefix}/tests/qt4/*"

do_configure_prepend() {
    sed -i 's:qtPrepareTool(LRELEASE, lrelease):LRELEASE = ${OE_QMAKE_LRELEASE}:g' \
        ${S}/translations/translations.pro

    sed -i \
    -e /QMAKE_MOC\ /d \
    -e /QMAKE_UIC\ /d \
    -e /QMAKE_UIC3\ /d \
    -e /QMAKE_RCC\ /d \
    ${S}/configure

    # Avoid problems with Qt 4.8.0 configure setting QMAKE_LINK from LD (since we want the linker to be g++)
    unset LD
}