5 files changed, 74 insertions, 2 deletions
diff --git a/conf/machine/dragonboard-820c.conf b/conf/machine/dragonboard-820c.conf
new file mode 100644
index 0000000..81f7672
--- /dev/null
+++ b/conf/machine/dragonboard-820c.conf
@@ -0,0 +1,21 @@
+#@TYPE: Machine
+#@NAME: dragonboard-820c
+#@DESCRIPTION: Machine configuration for the DragonBoard 820c (96boards), with Qualcomm Snapdragon 820 APQ8096.
+
+require conf/machine/include/qcom-apq8096.inc
+
+MACHINE_FEATURES = "usbhost usbgadget alsa screen wifi bluetooth ext2"
+
+KERNEL_IMAGETYPE = "Image"
+KERNEL_DEVICETREE = "qcom/apq8096-sbc.dtb"
+
+SERIAL_CONSOLE = "115200 ttyMSM0"
+
+MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS += " \
+    kernel-modules \
+"
+
+CMDLINE = "console=ttyMSM0,115200n8 root=/dev/sde18 rootwait"
+
+# UFS partitions setup with 4096 logical sector size
+EXTRA_IMAGECMD_ext4 += " -b 4096 "
diff --git a/conf/machine/include/qcom-apq8096.inc b/conf/machine/include/qcom-apq8096.inc
new file mode 100644
index 0000000..1cc0287
--- /dev/null
+++ b/conf/machine/include/qcom-apq8096.inc
@@ -0,0 +1,14 @@
+SOC_FAMILY = "apq8096"
+require conf/machine/include/soc-family.inc
+require conf/machine/include/arm/arch-armv8.inc
+
+PREFERRED_PROVIDER_virtual/egl ?= "mesa"
+PREFERRED_PROVIDER_virtual/libgl ?= "mesa"
+PREFERRED_PROVIDER_virtual/libgles1 ?= "mesa"
+PREFERRED_PROVIDER_virtual/libgles2 ?= "mesa"
+PREFERRED_PROVIDER_virtual/xserver ?= "xserver-xorg"
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-linaro-qcomlt-tracking"
+
+# Fastboot expects an ext4 image, which needs to be 4096 aligned
+IMAGE_FSTYPES_append = " ext4.gz"
+IMAGE_ROOTFS_ALIGNMENT = "4096"
diff --git a/recipes-kernel/linux/linux-linaro-qcomlt-tracking_4.6.bb b/recipes-kernel/linux/linux-linaro-qcomlt-tracking_4.6.bb
new file mode 100644
index 0000000..d011a1a
--- /dev/null
+++ b/recipes-kernel/linux/linux-linaro-qcomlt-tracking_4.6.bb
@@ -0,0 +1,37 @@
+# Copyright (C) 2014 Linaro
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Linaro Qualcomm Landing team 4.4 Kernel"
+
+require recipes-kernel/linux/linux-linaro-qcom.inc
+require recipes-kernel/linux/linux-dtb.inc
+require recipes-kernel/linux/linux-qcom-bootimg.inc
+
+LOCALVERSION ?= "-linaro-lt-qcom"
+SRCBRANCH ?= "integration-linux-qcomlt"
+SRCREV ?= "5574089362de2fb0ebbc0c4d9bd48203b59b7b1b"
+SRC_URI = "${LINUX_LINARO_QCOM_GIT};nobranch=1"
+
+COMPATIBLE_MACHINE = "(apq8064|apq8016|apq8096)"
+
+KERNEL_DEFCONFIG_aarch64 ?= "${S}/arch/arm64/configs/defconfig"
+KERNEL_DEFCONFIG_apq8064 ?= "${S}/arch/arm/configs/qcom_defconfig"
+KERNEL_CONFIG_FRAGMENTS += "${S}/kernel/configs/distro.config"
+
+# append DTB, since bootloader doesn't support DTB
+do_compile_append_apq8064() {
+    if ! [ -e ${B}/arch/${ARCH}/boot/dts/${KERNEL_DEVICETREE} ] ; then
+        oe_runmake ${KERNEL_DEVICETREE}
+    fi
+    cp ${KERNEL_OUTPUT} ${KERNEL_OUTPUT}.backup
+    cat ${KERNEL_OUTPUT}.backup ${B}/arch/${ARCH}/boot/dts/${KERNEL_DEVICETREE} > ${KERNEL_OUTPUT}
+    rm -f ${KERNEL_OUTPUT}.backup
+}
+
+# Wifi firmware has a recognizable arch :(
+ERROR_QA_remove = "arch"
+
+QCOM_BOOTIMG_ROOTFS_dragonboard-410c = "mmcblk0p10"
+QCOM_BOOTIMG_ROOTFS_dragonboard-820c = "sde18"
+QCOM_BOOTIMG_ROOTFS_ifc6410 = "mmcblk0p12"
+QCOM_BOOTIMG_ROOTFS_sd-600eval = "mmcblk0p12"
diff --git a/recipes-kernel/linux/linux-linaro-qcomlt_4.4.bb b/recipes-kernel/linux/linux-linaro-qcomlt_4.4.bb
index 1b1c451..64cd70c 100644
--- a/recipes-kernel/linux/linux-linaro-qcomlt_4.4.bb
+++ b/recipes-kernel/linux/linux-linaro-qcomlt_4.4.bb
@@ -13,7 +13,7 @@ SRCREV ?= "f404da21e128bc015dfcbb88d3daf2bcf18ef872"
 
 COMPATIBLE_MACHINE = "(ifc6410|sd-600eval|dragonboard-410c)"
 
-KERNEL_DEFCONFIG_apq8016 ?= "${S}/arch/arm64/configs/defconfig"
+KERNEL_DEFCONFIG_aarch64 ?= "${S}/arch/arm64/configs/defconfig"
 KERNEL_DEFCONFIG_apq8064 ?= "${S}/arch/arm/configs/qcom_defconfig"
 KERNEL_CONFIG_FRAGMENTS += "${S}/kernel/configs/distro.config"
 
diff --git a/recipes-kernel/linux/linux-qcom-bootimg.inc b/recipes-kernel/linux/linux-qcom-bootimg.inc
index 96e1496..b0e00a0 100644
--- a/recipes-kernel/linux/linux-qcom-bootimg.inc
+++ b/recipes-kernel/linux/linux-qcom-bootimg.inc
@@ -13,7 +13,7 @@ DT_IMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
 BOOT_IMAGE_BASE_NAME = "boot-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
 BOOT_IMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
 
-do_deploy_append_apq8016() {
+do_deploy_append_aarch64() {
 
     dtbTool -o ${DEPLOYDIR}/${DT_IMAGE_BASE_NAME}.img -s 2048 ${B}/arch/${ARCH}/boot/dts/qcom/