aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-extended/rxtx/rxtx_2.2.0.bb
blob: 87d84a80e5e1ad2cc66473e4689ad20d5f001046 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
SUMMARY = "Full Java CommAPI implementation"
DEPENDS = "virtual/javac-native"
LICENSE = "RXTXv2.1"
LIC_FILES_CHKSUM = "file://COPYING;md5=32303a23463f90b12a7d1dafb8deabf4"
PR = "r3"

SRC_URI = "http://rxtx.qbang.org/pub/rxtx/rxtx-2.2pre2.zip \
           file://zsystem_init_exception.patch \
           file://kfreebsd_port.patch \
           file://ttyACM_port.patch \
           file://original_debian_changes.patch \
           file://kfreebsd_libpthread.patch \
           file://sys_io_h_check.patch \
           file://port_to_hurd.patch \
           file://multiple_property_dirs.patch \
           file://uninstall_target.patch \
           file://fhs_lock_buffer_overflow_fix.patch \
           file://MonitorThread-daemon.patch \
           file://usb_38400.patch \
           file://fix_snprintf.patch \
           file://format_security.patch \
           file://0001-Support-Freescale-i.MX-serial-ports.patch \
           file://javapath.patch"

SRC_URI[md5sum] = "7eedb18e3f33a427e2b0e9be8ce3f94c"
SRC_URI[sha256sum] = "3c30373e760f444def3650c76c5a00ae12fb1d860ec008750d084f4880495b03"

S = "${WORKDIR}/rxtx-2.2pre2"

INSANE_SKIP_${JPN} += "dev-so"

PACKAGE_ARCH = "${TUNE_PKGARCH}"
inherit autotools-brokensep java-library remove-libtool

JARFILENAME = "RXTXcomm.jar"
EXTRA_OEMAKE += "RXTX_PATH=${D}${libdir_jni} \
                 JHOME=${D}${datadir_java}/ext"

do_configure_prepend() {
    # Ugly but don't complain to me, but upstream ;-)
    sed -e 's,bin/javah,bin/gjavah,g' \
        -e 's,bin/jar,bin/fastjar,g' \
        -e 's,\$(TOP)/libtool,\$(TOP)/\${host_alias}-libtool,g' -i ${S}/configure.in
    rm -f ${S}/acinclude.m4 \
          ${S}/aclocal.m4 \
          ${S}/ltconfig \
          ${S}/ltmain.sh
}

do_install_prepend() {
    install -d ${D}${libdir_jni}
    install -d ${D}${datadir_java}/ext
}

PACKAGES_remove = "${PN}"

FILES_${JPN} += "${libdir_jni}"
RPROVIDES_${JPN} = "${PN}"
RCONFLICTS_${JPN} = "${PN}"
RREPLACES_${JPN} = "${PN}"

FILES_${PN}-dbg += "${libdir_jni}/.debug"