aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-core/xml-commons/xpp3_1.1.3.4.O.bb
blob: a472a0d32990e43fbb0818c107389be0e7715524 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
DESCRIPTION = "Streaming pull XML parser for Java (3rd edition)"
LICENSE = "BSD-like"
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=35235e1ea47db355da0627f8d93e3a6c"

HOMEPAGE = "http://www.extreme.indiana.edu/xgws/xsoap/xpp/mxp1"

SRC_URI = "http://www.extreme.indiana.edu/dist/java-repository/xpp3/distributions/${P}_src.tgz"

inherit java-library

PACKAGES = "libxpp3-xpath-java ${JPN}"

do_compile() {
    if [ -d build-oe ]; then
        rm -rf build-oe
    fi
    mkdir -p build-oe

    sourcepath="src/java/api:src/java/builder:src/java/dom2_builder:src/java/mxp1_min:src/java/mxp1_standard:src/java/parser_pool:src/java/sax2_driver:src/java/serializer_impl:src/java/util:src/java/wrapper"
    findpath="${sourcepath//:/ }"

    javac -sourcepath $sourcepath -d build-oe `find $findpath -name "*.java"`

    mkdir -p build-oe/META-INF/services
    cp src/java/mxp1_standard/META-INF/services/org.xml* build-oe/META-INF/services
    fastjar -C build-oe -c -f ${JARFILENAME} .

    if [ -d build-xpath ]; then
        rm -rf build-xpath
    fi
    mkdir -p build-xpath

    sourcepath="src/java/xpath"
    findpath="${sourcepath//:/ }"
    javac -sourcepath $sourcepath -cp build-oe -d build-xpath `find $findpath -name "*.java"`

    fastjar -C build-xpath -c -f xpp3-xpath-${PV}.jar .
}

do_install_append() {
    oe_jarinstall xpp3-xpath-${PV}.jar xpp3-xpath.jar
}

FILES_libxpp3-xpath-java = "${datadir}/java/xpp3-xpath*"


SRC_URI[md5sum] = "e1b6aeaad1cd06e64568aae1a507d5c6"
SRC_URI[sha256sum] = "404c0cd332f54ecf9807dc86d365c17dcffab669994c9dcbbad31fbc4b59f811"