aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-extended/dbus/dbus-java_2.7.bb
diff options
context:
space:
mode:
authorHenning Heinold <heinold@inf.fu-berlin.de>2013-04-05 10:03:05 +0200
committerHenning Heinold <heinold@inf.fu-berlin.de>2013-04-05 10:04:35 +0200
commit499e44455e1c37f89dfb9be9e8a970c26e1311d0 (patch)
tree3482587c7d027e092a8a281b606a85dcd800fd6e /recipes-extended/dbus/dbus-java_2.7.bb
parent25ddfefe665ae48291d2ef3c88f4f1a74bad8768 (diff)
downloadmeta-java-499e44455e1c37f89dfb9be9e8a970c26e1311d0.tar.gz
meta-java-499e44455e1c37f89dfb9be9e8a970c26e1311d0.tar.bz2
meta-java-499e44455e1c37f89dfb9be9e8a970c26e1311d0.zip
recipes-extended: split out recipes which are not needed for compiling openjdk
Signed-off-by: Henning Heinold <heinold@inf.fu-berlin.de>
Diffstat (limited to 'recipes-extended/dbus/dbus-java_2.7.bb')
-rw-r--r--recipes-extended/dbus/dbus-java_2.7.bb92
1 files changed, 92 insertions, 0 deletions
diff --git a/recipes-extended/dbus/dbus-java_2.7.bb b/recipes-extended/dbus/dbus-java_2.7.bb
new file mode 100644
index 0000000..2fae051
--- /dev/null
+++ b/recipes-extended/dbus/dbus-java_2.7.bb
@@ -0,0 +1,92 @@
+DESCRIPTION = "A pure Java D-Bus Implementation"
+DESCRIPTION_dbus-java-viewer = "${DESCRIPTION} (DBusViewer Binary)"
+DESCRIPTION_dbus-java-bin = "${DESCRIPTION} (Binaries)"
+AUTHOR = "Matthew Johnson <dbus@matthew.ath.cx>"
+HOMEPAGE = "http://dbus.freedesktop.org/doc/dbus-java"
+SECTION = "libs"
+LICENSE = "LGPL-2.1 & AFL-2.1"
+
+DEPENDS = "libmatthew docbook-utils-native docbook-sgml-dtd-4.1-native fastjar-native"
+RDEPENDS_dbus-java-viewer = "java2-runtime libunixsocket-java dbus-java-bin libmatthew-debug-java ${JPN}"
+RDEPENDS_dbus-java-bin = "java2-runtime libunixsocket-java libmatthew-debug-java ${JPN}"
+RSUGGESTS_libdbus-java = "libunixsocket-java"
+
+PR = "r0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=72cc739fb93ae32741edbae802490e92"
+SRC_URI = "http://dbus.freedesktop.org/releases/dbus-java/dbus-java-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "8b8470db5cd657591bac245e3b6e18e4"
+SRC_URI[sha256sum] = "be404ea36284d938646192d0ee42e146853064217d4e3aaf89b56bd351ebca33"
+
+S = "${WORKDIR}/dbus-java-${PV}"
+
+inherit java-library
+
+# jamvm-native unfortunately contains non-generificed java/lang/reflect classes
+# which are accessed in this package. Work around this by setting the bootclasspath
+# explicitly.
+JCFLAGS = "-bootclasspath ${STAGING_DATADIR}/classpath/glibj.zip"
+
+do_compile () {
+ oe_runmake \
+ JCFLAGS="-source 1.5 ${JCFLAGS}" \
+ JAVAC="javac" \
+ JARPREFIX="${STAGING_DATADIR_JAVA}" \
+ JAVAUNIXJARDIR="${STAGING_DATADIR_JAVA}" \
+ JAVAUNIXLIBDIR="${STAGING_DIR_TARGET}${libdir_jni}" \
+ CLASSPATH="${S}/classes" \
+ JAR="fastjar" \
+ bin
+
+ # Generated shell scripts will have staging paths inside them.
+ rm bin/*
+
+ # Generate them again with target paths.
+ oe_runmake \
+ JAVAC="oefatal \"No Java compilation expected here.\"" \
+ JAR="oefatal \"No jar invocation expected here.\"" \
+ JARPREFIX=${datadir_java} \
+ JAVAUNIXJARDIR=${datadir_java} \
+ JAVAUNIXLIBDIR=${libdir_jni} \
+ bin
+
+ # Generate man pages.
+ oe_runmake \
+ JAVAC="oefatal \"No Java compilation expected here.\"" \
+ JAR="oefatal \"No jar invocation expected here.\"" \
+ JARPREFIX=${datadir_java} \
+ JAVAUNIXJARDIR=${datadir_java} \
+ JAVAUNIXLIBDIR=${libdir_jni} \
+ man
+}
+
+JARFILENAME = "${JPN}-${PV}.jar"
+
+do_install () {
+ oe_jarinstall ${JPN}-${PV}.jar ${JPN}.jar dbus.jar
+ oe_jarinstall dbus-java-viewer-${PV}.jar dbus-java-viewer.jar dbus-viewer.jar
+ oe_jarinstall dbus-java-bin-${PV}.jar dbus-java-bin.jar dbus-bin.jar
+
+ install -d ${D}${bindir}
+ install bin/DBusViewer ${D}${bindir}
+ install bin/DBusCall ${D}${bindir}
+ install bin/CreateInterface ${D}${bindir}
+ install bin/ListDBus ${D}${bindir}
+ install bin/DBusDaemon ${D}${bindir}
+
+ oe_runmake \
+ JAVAC="oefatal \"No Java compilation expected here.\"" \
+ JAR="oefatal \"No jar invocation expected here.\"" \
+ MANPREFIX=${D}${mandir} \
+ DOCPREFIX=${D}${docdir}/${JPN} \
+ install-man
+}
+
+# ${JPN} must be last otherwise it would pick up dbus-viewer*.jar
+# and dbus-bin*.jar
+PACKAGES = "dbus-java-viewer dbus-java-viewer-doc dbus-java-bin dbus-java-bin-doc ${JPN}"
+
+FILES_dbus-java-viewer = "${datadir}/java/dbus-java-viewer*.jar ${bindir}/DBusViewer"
+FILES_dbus-java-viewer-doc = "${mandir}/DBusViewer*"
+FILES_dbus-java-bin = "${datadir}/java/dbus-java-bin*.jar ${bindir}"
+FILES_dbus-java-bin-doc = "${mandir} ${docdir}/${JPN}"