aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-multimedia/pulseaudio/pulseaudio_5.0.bbappend
blob: e32efa72f314eb956e81196492535a9892c1d864 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"

SRC_URI_append = " file://pulseaudio.service"

PR = "r1"

inherit systemd

SYSTEMD_PACKAGES = "${PN}-server"
SYSTEMD_SERVICE = "pulseaudio.service"

PACKAGECONFIG_remove = "bluez4"
PACKAGECONFIG_append = " bluez5"

RDEPENDS_pulseaudio-module-systemd-login =+ "systemd"
RDEPENDS_pulseaudio-server += "\
        ${@base_contains('DISTRO_FEATURES', 'x11', 'pulseaudio-module-systemd-login', '', d)}"

python __anonymous () {
    '''
    If DISTRO_FEATURES include systemd use pulseaudio-module-systemd-login as a
    replacer for pulseaudio-module-console-kit.
    '''
    distro_features = d.getVar('DISTRO_FEATURES', True).split()
    if 'systemd' in distro_features:
        new_rdeps = []
        old_rdeps = d.getVar('RDEPENDS_pulseaudio-server', True).split()
        for rdep in old_rdeps:
            if rdep != 'pulseaudio-module-console-kit':
                new_rdeps.append(rdep)
        d.setVar('RDEPENDS_pulseaudio-server', ' '.join(new_rdeps))
}

do_install_append() {
    if ${@base_contains('DISTRO_FEATURES','systemd','true','false',d)}; then
        install -d ${D}${systemd_unitdir}/system/
        install -m 0644 ${WORKDIR}/pulseaudio.service ${D}${systemd_unitdir}/system
    fi
}