aboutsummaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
authorFlorin Sarbu <florin.sarbu@windriver.com>2014-09-18 15:56:25 +0300
committerHolger Behrens <holger.behrens@windriver.com>2014-10-17 17:29:10 +0200
commit1fab1d5e8eafd8754e1a5d67056f32961e8db46d (patch)
treeb38fac98e27640d9738894bce5ba82ab1cdc23cd
parent21ca4c1d11451d9ec70f62d760104522c77aeebf (diff)
downloadmeta-ivi-1fab1d5e8eafd8754e1a5d67056f32961e8db46d.tar.gz
meta-ivi-1fab1d5e8eafd8754e1a5d67056f32961e8db46d.tar.bz2
meta-ivi-1fab1d5e8eafd8754e1a5d67056f32961e8db46d.zip
xserver-xorg: Add version 1.16 with xwayland support
Signed-off-by: Florin Sarbu <florin.sarbu@windriver.com> Signed-off-by: Holger Behrens <holger.behrens@windriver.com>
-rw-r--r--meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg.inc159
-rw-r--r--meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/fix_open_max_preprocessor_error.patch15
-rw-r--r--meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xorg-CVE-2013-6424.patch31
-rw-r--r--meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xshmfence-option.patch55
-rw-r--r--meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg_1.16.0.bb42
5 files changed, 302 insertions, 0 deletions
diff --git a/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg.inc b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg.inc
new file mode 100644
index 0000000..1ac030f
--- /dev/null
+++ b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg.inc
@@ -0,0 +1,159 @@
+SUMMARY = "The X.Org X server"
+HOMEPAGE = "http://www.x.org"
+SECTION = "x11/base"
+LICENSE = "MIT-X"
+LIC_FILES_CHKSUM = "file://COPYING;md5=15b5bf9327341c81089137aec4830bfd"
+
+# xf86-*-* packages depend on an X server built with the xfree86 DDX
+# so we have a virtual to represent that:
+# deprecated, we should use virtual/xserver instead
+PROVIDES = "virtual/xserver-xf86"
+
+# Other packages tend to just care that there is *an* X server:
+PROVIDES += "virtual/xserver"
+
+PE = "2"
+INC_PR = "r8"
+
+XORG_PN = "xorg-server"
+SRC_URI = "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${PV}.tar.bz2"
+SRC_URI += "file://macro_tweak.patch"
+
+S = "${WORKDIR}/${XORG_PN}-${PV}"
+
+inherit autotools pkgconfig
+
+PROTO_DEPS = "randrproto renderproto fixesproto damageproto xextproto xproto xf86dgaproto xf86miscproto xf86vidmodeproto compositeproto recordproto resourceproto videoproto scrnsaverproto xineramaproto fontsproto kbproto inputproto bigreqsproto xcmiscproto presentproto"
+LIB_DEPS = "pixman libxfont xtrans libxau libxext libxdmcp libdrm libxkbfile libpciaccess openssl libgcrypt"
+DEPENDS = "${PROTO_DEPS} ${LIB_DEPS} font-util"
+
+# Split out some modules and extensions from the main package
+# These aren't needed for basic operations and only take up space:
+# 32.0k libdri.so
+# 91.0k libexa.so
+# 336.0k libglx.so
+# 1360k libint10.so
+# 180.0k libwfb.so
+# 320.0k libxaa.so
+# 124.0k libxf1bpp.so
+# 84.0k libxf4bpp.so
+# librecord.so
+# libextmod.so
+# libdbe.so
+
+PACKAGES =+ "${PN}-security-policy \
+ ${PN}-sdl \
+ ${PN}-fbdev \
+ ${PN}-xvfb \
+ ${PN}-utils \
+ ${PN}-xephyr \
+ ${PN}-multimedia-modules \
+ ${PN}-extension-dri \
+ ${PN}-extension-dri2 \
+ ${PN}-extension-glx \
+ ${PN}-extension-record \
+ ${PN}-extension-extmod \
+ ${PN}-extension-dbe \
+ ${PN}-module-libint10 \
+ ${PN}-module-libafb \
+ ${PN}-module-libwfb \
+ ${PN}-module-libmfb \
+ ${PN}-module-libcfb \
+ ${PN}-module-exa \
+ ${PN}-module-xaa \
+ ${PN}-module-libxf1bpp \
+ ${PN}-module-libxf4bpp"
+
+RRECOMMENDS_${PN} += "${PN}-security-policy xkeyboard-config rgb xserver-xf86-config xkbcomp"
+RDEPENDS_${PN}-xvfb += "xkeyboard-config"
+RDEPENDS_${PN}-module-exa = "${PN} (= ${EXTENDPKGV})"
+
+FILES_${PN} = "${bindir} ${libdir}/X11/Options ${libdir}/X11/Cards ${libdir}/X11/getconfig ${libdir}/X11/etc ${libdir}/modules/*.so ${libdir}/xorg/modules/*.so /etc/X11 ${libdir}/xorg/protocol.txt ${datadir}/X11/xorg.conf.d"
+FILES_${PN}-dev += "${libdir}/xorg/modules/*.la ${libdir}/xorg/modules/*/*.la"
+FILES_${PN}-doc += "${libdir}/X11/doc ${datadir}/X11/xkb/compiled/README.compiled ${localstatedir}/lib/xkb/README.compiled"
+FILES_${PN}-dbg += "${libdir}/xorg/modules/.debug \
+ ${libdir}/xorg/modules/*/.debug \
+ ${libdir}/xorg/modules/*/*/.debug \
+ "
+FILES_${PN}-security-policy += "${libdir}/xserver/SecurityPolicy"
+FILES_${PN}-sdl = "${bindir}/Xsdl"
+FILES_${PN}-fbdev = "${bindir}/Xfbdev"
+FILES_${PN}-xvfb = "${bindir}/Xvfb"
+FILES_${PN}-utils = "${bindir}/scanpci ${bindir}/pcitweak ${bindir}/ioport ${bindir}/in[bwl] ${bindir}/out[bwl] ${bindir}/mmap[rw] ${bindir}/gtf ${bindir}/getconfig ${bindir}/getconfig.pl"
+FILES_${PN}-xephyr = "${bindir}/Xephyr"
+FILES_${PN}-multimedia-modules = "${libdir}/xorg/modules/multimedia/*drv*"
+FILES_${PN}-extension-dri = "${libdir}/xorg/modules/extensions/libdri.so"
+FILES_${PN}-extension-dri2 = "${libdir}/xorg/modules/extensions/libdri2.so"
+FILES_${PN}-extension-glx = "${libdir}/xorg/modules/extensions/libglx.so"
+FILES_${PN}-extension-record = "${libdir}/xorg/modules/extensions/librecord.so"
+FILES_${PN}-extension-extmod = "${libdir}/xorg/modules/extensions/libextmod.so"
+FILES_${PN}-extension-dbe = "${libdir}/xorg/modules/extensions/libdbe.so"
+FILES_${PN}-module-libint10 = "${libdir}/xorg/modules/libint10.so"
+FILES_${PN}-module-libafb = "${libdir}/xorg/modules/libafb.so"
+FILES_${PN}-module-libwfb = "${libdir}/xorg/modules/libwfb.so"
+FILES_${PN}-module-libmfb = "${libdir}/xorg/modules/libmfb.so"
+FILES_${PN}-module-libcfb = "${libdir}/xorg/modules/libcfb.so"
+FILES_${PN}-module-exa = "${libdir}/xorg/modules/libexa.so"
+FILES_${PN}-module-xaa = "${libdir}/xorg/modules/libxaa.so"
+FILES_${PN}-module-libxf1bpp = "${libdir}/xorg/modules/libxf1bpp.so"
+FILES_${PN}-module-libxf4bpp = "${libdir}/xorg/modules/libxf4bpp.so"
+
+EXTRA_OECONF += "--with-fop=no \
+ --with-pic \
+ --disable-static \
+ --disable-xinerama \
+ --disable-record \
+ --disable-dmx \
+ --disable-xnest \
+ --enable-xvfb \
+ --enable-composite \
+ --without-dtrace \
+ --with-int10=x86emu \
+ --sysconfdir=/etc/X11 \
+ --localstatedir=/var \
+ --with-xkb-output=/var/lib/xkb \
+ --with-sha1=libcrypto \
+ ac_cv_file__usr_share_sgml_X11_defs_ent=no \
+"
+
+PACKAGECONFIG ??= "udev ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'dri dri2 glx', '', d)}"
+PACKAGECONFIG[udev] = "--enable-config-udev,--disable-config-udev,udev"
+PACKAGECONFIG[dri] = "--enable-dri,--disable-dri,glproto virtual/mesa xf86driproto"
+PACKAGECONFIG[dri2] = "--enable-dri2,--disable-dri2,dri2proto"
+# DRI3 requires xshmfence to also be enabled
+PACKAGECONFIG[dri3] = "--enable-dri3,--disable-dri3,dri3proto"
+PACKAGECONFIG[glx] = "--enable-glx --enable-glx-tls,--disable-glx,glproto virtual/libgl virtual/libx11"
+PACKAGECONFIG[unwind] = "--enable-libunwind,--disable-libunwind,libunwind"
+PACKAGECONFIG[xshmfence] = "--enable-xshmfence,--disable-xshmfence,libxshmfence"
+PACKAGECONFIG[xmlto] = "--with-xmlto, --without-xmlto, xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native"
+
+do_install_append () {
+ # Its assumed base-files creates this for us
+ rm -rf ${D}${localstatedir}/log/
+}
+
+# Add runtime provides for the ABI versions of the video and input subsystems,
+# so that drivers can depend on the relevant version.
+python populate_packages_prepend() {
+ import subprocess
+
+ # Set PKG_CONFIG_PATH so pkg-config looks at the .pc files that are going
+ # into the new package, not the staged ones.
+ newenv = dict(os.environ)
+ newenv["PKG_CONFIG_PATH"] = d.expand("${PKGD}${libdir}/pkgconfig/")
+
+ def get_abi(name):
+ abis = {
+ "video": "abi_videodrv",
+ "input": "abi_xinput"
+ }
+ p = subprocess.Popen(args="pkg-config --variable=%s xorg-server" % abis[name],
+ shell=True, env=newenv, stdout=subprocess.PIPE)
+ output = p.communicate()[0]
+ mlprefix = d.getVar('MLPREFIX', True) or ''
+ return "%sxorg-abi-%s-%s" % (mlprefix, name, output.split(".")[0])
+
+ pn = d.getVar("PN", True)
+ d.appendVar("RPROVIDES_" + pn, " " + get_abi("input"))
+ d.appendVar("RPROVIDES_" + pn, " " + get_abi("video"))
+}
diff --git a/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/fix_open_max_preprocessor_error.patch b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/fix_open_max_preprocessor_error.patch
new file mode 100644
index 0000000..2f62972
--- /dev/null
+++ b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/fix_open_max_preprocessor_error.patch
@@ -0,0 +1,15 @@
+Upstream-Status: Pending
+
+Index: git/os/osdep.h
+===================================================================
+--- git.orig/os/osdep.h 2008-10-07 18:38:21.000000000 +0100
++++ git/os/osdep.h 2008-10-07 18:39:36.000000000 +0100
+@@ -92,7 +92,7 @@
+ * like sysconf(_SC_OPEN_MAX) is not supported.
+ */
+
+-#if OPEN_MAX <= 256
++#if 0
+ #define MAXSOCKS (OPEN_MAX - 1)
+ #else
+ #define MAXSOCKS 256
diff --git a/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xorg-CVE-2013-6424.patch b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xorg-CVE-2013-6424.patch
new file mode 100644
index 0000000..7c61530
--- /dev/null
+++ b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xorg-CVE-2013-6424.patch
@@ -0,0 +1,31 @@
+This patch comes from:
+http://lists.x.org/archives/xorg-devel/2013-October/037996.html
+
+Upstream-Status: Backport
+
+Signed-off-by: Baogen shang <baogen.shang@windriver.com>
+diff -Naur xorg-server-1.14.0-orig/exa/exa_render.c xorg-server-1.14.0/exa/exa_render.c
+--- xorg-server-1.14.0-orig/exa/exa_render.c 2014-02-27 14:32:38.000000000 +0800
++++ xorg-server-1.14.0/exa/exa_render.c 2014-02-27 15:46:59.000000000 +0800
+@@ -1141,7 +1141,8 @@
+
+ exaPrepareAccess(pPicture->pDrawable, EXA_PREPARE_DEST);
+ for (; ntrap; ntrap--, traps++)
+- (*ps->RasterizeTrapezoid) (pPicture, traps, -bounds.x1, -bounds.y1);
++ if (xTrapezoidValid(traps))
++ (*ps->RasterizeTrapezoid) (pPicture, traps, -bounds.x1, -bounds.y1);
+ exaFinishAccess(pPicture->pDrawable, EXA_PREPARE_DEST);
+
+ xRel = bounds.x1 + xSrc - xDst;
+diff -Naur xorg-server-1.14.0-orig/render/picture.h xorg-server-1.14.0/render/picture.h
+--- xorg-server-1.14.0-orig/render/picture.h 2014-02-27 14:32:26.000000000 +0800
++++ xorg-server-1.14.0/render/picture.h 2014-02-27 15:48:13.000000000 +0800
+@@ -211,7 +211,7 @@
+ /* whether 't' is a well defined not obviously empty trapezoid */
+ #define xTrapezoidValid(t) ((t)->left.p1.y != (t)->left.p2.y && \
+ (t)->right.p1.y != (t)->right.p2.y && \
+- (int) ((t)->bottom - (t)->top) > 0)
++ ((t)->bottom > (t)->top))
+
+ /*
+ * Standard NTSC luminance conversions:
diff --git a/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xshmfence-option.patch b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xshmfence-option.patch
new file mode 100644
index 0000000..55e0913
--- /dev/null
+++ b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg/xshmfence-option.patch
@@ -0,0 +1,55 @@
+Upstream-Status: Submitted
+Signed-off-by: Ross Burton <ross.burton@intel.com>
+
+commit 1affe20d5c82befc3b1626e557409dab5343c47b
+Author: Ross Burton <ross.burton@intel.com>
+Date: Mon Jul 7 12:53:35 2014 +0100
+
+ configure.ac: add option for xshmfence
+
+ xshmfence is usable outside of DRI3, and is currently autodetected which isn't
+ good for distributions where deterministic builds are aspired to.
+
+ Signed-off-by: Ross Burton <ross.burton@intel.com>
+
+diff --git a/configure.ac b/configure.ac
+index 2daa6be..fd1cf3f 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -648,6 +648,7 @@ AC_ARG_ENABLE(kdrive-kbd, AS_HELP_STRING([--enable-kdrive-kbd], [Build kbd d
+ AC_ARG_ENABLE(kdrive-mouse, AS_HELP_STRING([--enable-kdrive-mouse], [Build mouse driver for kdrive (default: auto)]), [KDRIVE_MOUSE=$enableval], [KDRIVE_MOUSE=auto])
+ AC_ARG_ENABLE(kdrive-evdev, AS_HELP_STRING([--enable-kdrive-evdev], [Build evdev driver for kdrive (default: auto)]), [KDRIVE_EVDEV=$enableval], [KDRIVE_EVDEV=auto])
+ AC_ARG_ENABLE(libunwind, AS_HELP_STRING([--enable-libunwind], [Use libunwind for backtracing (default: auto)]), [LIBUNWIND="$enableval"], [LIBUNWIND="auto"])
++AC_ARG_ENABLE(xshmfence, AS_HELP_STRING([--disable-xshmfence], [Disable xshmfence (default: auto)]), [WANT_XSHMFENCE="$enableval"], [WANT_XSHMFENCE="auto"])
+
+
+ dnl chown/chmod to be setuid root as part of build
+@@ -1235,18 +1236,19 @@ esac
+
+ AM_CONDITIONAL(BUSFAULT, test x"$BUSFAULT" = xyes)
+
+-PKG_CHECK_MODULES([XSHMFENCE], $XSHMFENCE,
+- [HAVE_XSHMFENCE=yes], [HAVE_XSHMFENCE=no])
++HAVE_XSHMFENCE=no
++if test "x$WANT_XSHMFENCE" != "xno"; then
++ PKG_CHECK_MODULES([XSHMFENCE], $XSHMFENCE,
++ [HAVE_XSHMFENCE=yes], [HAVE_XSHMFENCE=no])
+
++ if test "$WANT_XSHMFENCE,$HAVE_XSHMFENCE" = "yes,no"; then
++ AC_MSG_ERROR([libxshmfence requested but not found.])
++ fi
++ AC_DEFINE(HAVE_XSHMFENCE, 1, [Have X Shared Memory Fence library])
++ REQUIRED_LIBS="$REQUIRED_LIBS xshmfence"
++fi
+ AM_CONDITIONAL(XSHMFENCE, test "x$HAVE_XSHMFENCE" = xyes)
+
+-case x"$HAVE_XSHMFENCE" in
+- xyes)
+- AC_DEFINE(HAVE_XSHMFENCE, 1, [Have X Shared Memory Fence library])
+- REQUIRED_LIBS="$REQUIRED_LIBS xshmfence"
+- ;;
+-esac
+-
+
+ case "$DRI3,$HAVE_XSHMFENCE" in
+ yes,yes | auto,yes)
diff --git a/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg_1.16.0.bb b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg_1.16.0.bb
new file mode 100644
index 0000000..34e8e9d
--- /dev/null
+++ b/meta-ivi-demo/recipes-graphics/xorg-xserver/xserver-xorg_1.16.0.bb
@@ -0,0 +1,42 @@
+require xserver-xorg.inc
+
+# Misc build failure for master HEAD
+SRC_URI += "file://fix_open_max_preprocessor_error.patch \
+ file://xorg-CVE-2013-6424.patch \
+ file://xshmfence-option.patch \
+ "
+
+SRC_URI[md5sum] = "8a9ff6ee9907360f09b5bdabb8089502"
+SRC_URI[sha256sum] = "38330a03c5f7a38745a3f9816cf069db5b8844eebb358fd39dbabf61f32cd06b"
+
+
+DEPENDS_append =" libepoxy"
+
+PACKAGECONFIG_remove = "glx"
+
+EXTRA_OECONF += "--disable-docs --disable-devel-docs \
+ --enable-xwayland --disable-xorg --disable-xvfb --disable-xnest \
+ --disable-xquartz --disable-xwin \
+ "
+
+# These extensions are now integrated into the server, so declare the migration
+# path for in-place upgrades.
+
+RREPLACES_${PN} = "${PN}-extension-dri \
+ ${PN}-extension-dri2 \
+ ${PN}-extension-record \
+ ${PN}-extension-extmod \
+ ${PN}-extension-dbe \
+ "
+RPROVIDES_${PN} = "${PN}-extension-dri \
+ ${PN}-extension-dri2 \
+ ${PN}-extension-record \
+ ${PN}-extension-extmod \
+ ${PN}-extension-dbe \
+ "
+RCONFLICTS_${PN} = "${PN}-extension-dri \
+ ${PN}-extension-dri2 \
+ ${PN}-extension-record \
+ ${PN}-extension-extmod \
+ ${PN}-extension-dbe \
+ "