aboutsummaryrefslogtreecommitdiffstats
path: root/recipes-graphics/xorg-driver/xf86-dri-vivante_1.1.0.bb
blob: 6e8f8dba752c7f17f1ed555ea904902540e89772 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Copyright (C) 2012-2013 Freescale Semiconductor
# Copyright (C) 2012-2013 O.S. Systems Software LTDA.
# Released under the MIT license (see COPYING.MIT for the terms)

LICENSE = "MIT"
SECTION = "x11/base"
DEPENDS = "virtual/xserver xf86-video-imxfb-vivante"
LIC_FILES_CHKSUM = "file://src/dri.h;enline=27;md5=1d0d59e1dc96f5197ea3a8b101bf1fcc"

SRC_URI = "${FSL_MIRROR}/xserver-xorg-video-imx-viv-${PV}.tar.gz \
           file://fix-libdrm-link.patch"
SRC_URI[md5sum] = "d872365c046738628a7016343ffdb79a"
SRC_URI[sha256sum] = "d53216d5f9e3f7803983ac1577d83985dfda33145e4711300f4ad5cbbe28e32d"

PE = "1"
PR = "r0"

S = "${WORKDIR}/xserver-xorg-video-imx-viv-${PV}/DRI_1.10.4"

inherit fsl-eula-unpack autotools pkgconfig

EXTRA_OECONF_armv7a = " --enable-neon "
CFLAGS += " -I${STAGING_INCDIR}/xorg -DXSERVER_LIBPCIACCESS"

do_install_append () {
    # Install header files
    install -d ${D}${includedir}/xorg
    cp -axr ${S}/src/*.h ${D}${includedir}/xorg
    find ${D}${includedir} -type f -exec chmod 660 {} \;

    # FIXME: don't install libtool (*.la) file
    rm ${D}${libdir}/xorg/modules/extensions/*.la

    # FIXME: The Xorg driver has a hardcoded library name
    mv ${D}${libdir}/xorg/modules/extensions/libdri.so \
       ${D}${libdir}/xorg/modules/extensions/libvivante_dri.so
}

FILES_${PN}-dev += "${includedir}/xorg/*.h"
FILES_${PN} += " ${libdir}/xorg/modules/extensions/*.so"
FILES_${PN}-dbg += " ${libdir}/xorg/modules/extensions/.debug"

RDEPENDS_${PN} += "xserver-xorg-extension-glx"

PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_MACHINE = "(mx6)"