blob: b01339b625bf3211ee0b6742a298cfe2ac30b7af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
SUMMARY = "OP-TEE sanity testsuite"
HOMEPAGE = "https://github.com/qoriq-open-source/optee_test"
LICENSE = "BSD & GPLv2"
LIC_FILES_CHKSUM = "file://${S}/LICENSE.md;md5=daa2bcccc666345ab8940aab1315a4fa"
DEPENDS = "optee-client-qoriq optee-os-qoriq python-pycrypto-native"
inherit pythonnative
SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/optee_test;nobranch=1 \
file://0001-fix-build-failure-with-GCC-8.patch \
"
S = "${WORKDIR}/git"
SRCREV = "a54952babb83d801148867bd639a24ff6cd36f00"
OPTEE_CLIENT_EXPORT = "${STAGING_DIR_HOST}${prefix}"
TEEC_EXPORT = "${STAGING_DIR_HOST}${prefix}"
TA_DEV_KIT_DIR = "${STAGING_INCDIR}/optee/export-user_ta"
EXTRA_OEMAKE = " TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
CFG_ARM64=y \
CROSS_COMPILE_HOST=${TARGET_PREFIX} \
CROSS_COMPILE_TA=${TARGET_PREFIX} \
V=1 \
"
do_compile() {
# Top level makefile doesn't seem to handle parallel make gracefully
oe_runmake xtest
oe_runmake ta
}
do_install () {
install -D -p -m0755 ${S}/out/xtest/xtest ${D}${bindir}/xtest
# install path should match the value set in optee-client/tee-supplicant
# default TEEC_LOAD_PATH is /lib
mkdir -p ${D}/lib/optee_armtz/
install -D -p -m0444 ${S}/out/ta/*/*.ta ${D}/lib/optee_armtz/
}
FILES_${PN} += "/lib/optee_armtz/"
# Imports machine specific configs from staging to build
PACKAGE_ARCH = "${MACHINE_ARCH}"
COMPATIBLE_MACHINE = "(ls1043ardb|ls1046ardb|ls1012ardb)"
|
