1 files changed, 53 insertions, 0 deletions
diff --git a/common/recipes-graphics/mesa/mesa_19.0.1.bbappend b/common/recipes-graphics/mesa/mesa_19.0.1.bbappend
new file mode 100644
index 00000000..07695036
--- /dev/null
+++ b/common/recipes-graphics/mesa/mesa_19.0.1.bbappend
@@ -0,0 +1,53 @@
+DEPENDS_append_amd = " libvdpau libomxil"
+
+PACKAGECONFIG[va] = "--enable-va,--disable-va,libva"
+PACKAGECONFIG_append_amd = " xvmc gallium r600 gallium-llvm xa"
+PACKAGECONFIG_append_radeon = " va"
+PACKAGECONFIG_append_amdgpu = " va"
+
+PACKAGECONFIG_remove_amd = "vulkan"
+PACKAGECONFIG_remove_amdfalconx86 = "xvmc"
+
+LIBVA_PLATFORMS  = "libva"
+LIBVA_PLATFORMS .= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', ' libva-x11', '', d)}"
+LIBVA_PLATFORMS .= "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', ' libva-wayland', '', d)}"
+RDEPENDS_mesa-megadriver += "${@bb.utils.contains('PACKAGECONFIG', 'va', '${LIBVA_PLATFORMS}', '', d)}"
+
+EXTRA_OECONF_append_amd = " \
+		 --enable-vdpau \
+		 --enable-osmesa \
+		 --enable-glx \
+		 --enable-omx-bellagio \
+		 --with-omx-bellagio-libdir=${libdir}/bellagio"
+EXTRA_OECONF_remove_amd = "--enable-texture-float"
+
+# Package all the libXvMC gallium extensions together
+# they provide the shared lib libXvMCGallium and splitting
+# them up creates trouble in rpm packaging
+PACKAGES =+ "libxvmcgallium-${PN} libxvmcgallium-${PN}-dev"
+FILES_libxvmcgallium-${PN} = "${libdir}/libXvMC*${SOLIBS}"
+FILES_libxvmcgallium-${PN}-dev = "${libdir}/libXvMC*${SOLIBSDEV} \
+                               ${libdir}/libXvMC*.la"
+
+PACKAGES =+ "libvdpau-${PN} libvdpau-${PN}-dev"
+FILES_libvdpau-${PN} = "${libdir}/vdpau/libvdpau*${SOLIBS}"
+FILES_libvdpau-${PN}-dev = "${libdir}/vdpau/libvdpau*${SOLIBSDEV} \
+                            ${libdir}/vdpau/libvdpau*.la"
+FILES_${PN}-dbg += "${libdir}/vdpau/.debug"
+
+#
+# libomx files are non-versioned so we put *.so directly in the
+# main package as opposed to the -dev package.
+#
+PACKAGES =+ "libomx-${PN} libomx-${PN}-dev ${PN}-driconfigs"
+FILES_libomx-${PN} = "${libdir}/bellagio/libomx_*.so"
+FILES_libomx-${PN}-dev = "${libdir}/bellagio/libomx_*.la"
+FILES_${PN}-driconfigs = "${datadir}/drirc.d/*"
+FILES_${PN}-dbg += "${libdir}/bellagio/.debug"
+
+# Set DRIDRIVERS with anonymous python so we can effectively
+# override the _append_x86-64 assignement from mesa.inc.
+python () {
+    d.setVar("DRIDRIVERS", "swrast,radeon")
+    d.setVar("GALLIUMDRIVERS", "swrast,r300,r600,radeonsi")
+}